前回で、boot対応のモニタができましたので、早速biosを作成して、CP/Mをブートしたい思います。
CP/Mファイルシステムは、「Z80に萌えたい CP/M ディスク容量拡張その2」を参考に、SDCARDに焼きこみます。
(128トラック/64セクタ/4ドライブ)
次にCP/Mシステムですが、CCP+BDOS+BIOSで構成されBIOSは今回製作します。CCP+BDOSは下記手順で別途入手する必要があります。
以前「Z80(TMPZ84C015)に萌えたい。CPM BIOS編1」で 紹介したサイトの「Digital Research Binary Files」「OPERATING SYSTEMS」から CP/M 2.2 のCP/M2.2 BINARY をダウンロードします。cpm22-b.zipというファイルでダウロードされますので、解凍します。解凍したフォルダーの中から CPM.SYSというファイルを使用します。
このCPM.SYSというファイルにはCCPとBDOSとBIOSが一緒にパッケージされています。このCPM.SYSのメモリサイズエリアは、62K CP/Mで、ロードアドレスは、0xDC00となっています。
作成したモニタではSYS形式のファイルは読み込めないので、一旦hexファイルに変換します。
HEXコンバートを行うソフトですが今旬なPythonを使うことにします。
Pythonで記述されたIntelHexというライブラリーがあり、その中にオブジェクトをHEXコードに変換する実行コマンドが含まれています。
では早速インストールしたいと思います。(今まで通りRaspberryPiのRaspbianでの環境で確認しています。)
ライブラリのインストール
pythonのパッケージ管理コマンドのpipコマンドでインストールします。
$ sudo pip install intelhex
cpm.sysをHEXファイルに変換します。ロードアドレスは。前述のように0xdc00とします。
コマンド名は bin2hex.py オフセットアドレス、入力ファイル、出力ファイルを順に指定します。ここでは出力ファイル名としてcpm.hexとしました。
$ sudo python /usr/local/bin/bin2hex.py --offset=0xdc00 CPM.SYS cpm.hex
モニタのtコマンドで64Kメモリに切り替えてから、lコマンドで先ほどのcpm.hexを読み込みます。0xdc00以降にccp、bdos、biosと書き込まれます。
ただしbiosは、作成したものを上書きします。
BIOSをアセンブルします。(文末にソース・HEXファイルがあります)
ここでは、ファイル名をKL5C80_bios_sk0_64_128_4.asmとしました。
作成されたKL5C80_bios_sk0_64_128_4.ihxをモニタlコマンドで読み込みbiosを上書きします。
今の状況では、メモリ上でCP/Mシステムが構成されていますが、これをSDCARDのトラック0のシステム領域に書き込みします。
これは書き込みソフトKL5C80_cpm_rw(文末にソース・HEXファイルがあります)を使用します。
KL5C80_cpm_rw.ihxを同じくlコマンドで読み込みます。
jコマンドで 0x8000へジャンプします。
>j 8000 y:
:SDHC
read >> r :write >> w CP/M go >> g key in:
SDCARDにシステム(CCP+BDOS)書き込みします。
wキーでwriteを選択し、0000ブロックから000bブロック、アドレスdc00より書き込み指定し、yキーで書き込み実行します。
read/write start block No:0000
read/write block:000b
read/write addr:dc00
Yes: read/write ok!
続いてBIOSを書き込みます。
000bブロックから 0004ブロック、アドレスf200より書き込みしてします。
>j 8000 y:
:SDHC
read >> r :write >> w CP/M go >> g key in:w
read/write start block No:000b
read/write block:0004
read/write addr:f200
Yes: read/write ok!
>
今度は、モニタのbキーでCP/Mシステムをbootします。
>b
CP/M boot ? yes:
CMD0:01
CMD8:01000001AA
CMD55:01
ACMD41:01
CMD55:01
ACMD41:00
:SDHC
CP/M boot ....
:SDHC
62K CP/M VERS 2.2
A>dir
A: ASM COM : DDT COM : DISKDEF LIB : DUMP COM
A: ED COM : LOAD COM : MAC COM : PIP COM
A: STAT COM : SUBMIT COM : XSUB COM : Z80 LIB
A>
ちゃんとブートしたみたいです^^
以下 BIOSのソースとHEXファイルです。その後にKL5C80_cpm_rwのソースとHEXファイルを添付しています。
BIOSのソース
;;z80 (KL5C80B12) 62K cp/m V2.2 BIOS 64sector*128track by Pinecone 2020/11/19
; KL5C80B12 cpu
; ram 0000h -- ffffh
; clock 10MHz(ext.clock 20MHz)
; KL5C80B12 serial communication
; extemal Clock 614.4KHz(4.9152MHz TC74HC4040 1/8 Frequency division)
; Band Rate:38400 8bits 1Stopbits none Parity (81N)
; assembler
; program start 0xF200
; main 0xF200
;
; assemblers ASxxxx and ASlink V5.10
; file name KL5C80_bios_sk0_64_128_4.asm
; $ asz80 -l -s -o KL5C80_bios_sk0_64_128_4.asm
; $ aslink -i KL5C80_bios_sk0_64_128_4
; $ KL5C80_moni72 l command Hex load jump 0xf200
.z80
VERS .equ 22 ;Version 2.2
MSIZE .equ 62 ;CP/M memory size
BIAS .equ (MSIZE-20)*1024
CCP .equ 0x3400 + BIAS ;base of cpm console processor
BDOS .equ 0x806 + CCP ;basic dos
BIOS .equ CCP + 0x1600 ;BIOS
IOBYTE .equ 0x0003 ;intel i/o byte
cpmboot .equ CCP
TRACK_OFFSET .equ 1 ;cp/m used tracks number
;;KL5C80B12 System control register
SCR0 .equ 0x3a
SCR1 .equ 0x3b
;;KL5C80 Memory management unit
BBR1 .equ 0x00
BR1 .equ 0x01
BBR2 .equ 0x02
BR2 .equ 0x03
BBR3 .equ 0x04
BR3 .equ 0x05
BBR4 .equ 0x06
BR4 .equ 0x07
;;KL5C80 UART
UART_D .equ 0x38
UART_C .equ 0x39
;;KL5C80 Parallel port B
PP2D .equ 0x30
PP3D .equ 0x31
PP4D .equ 0x32
PPBC .equ 0x33
;; KL5C80B12 pio SPI OUT-PORT PIO-B 2x
S_DI .equ 7 ;0b10000000 D7
S_CS .equ 6 ;0b01000000 D6
S_CLK .equ 5 ;0b00100000 D5
;; KL5C80B12 pio SPI OUT-PORT PIO-B 2x
DO .equ 0 ;0b00000001 D0
BUFF_DEFAULT_ADDR .equ 0x80 ;default buff address
DISKS_MAX .equ 4 ;max disk
DISK_TRACK .equ 128 ;1 disk>> 128 track
DISK_SECTOR .equ 64 ;1 track>> 64 sector
.area BIOS(ABS)
.org BIOS
;; jump vector for indiviual routines
;
jp boot ;cold start
wboote: jp wboot ;warm start
jp const ;console status
jp conin ;console character in
jp conout ;console character out
jp list ;list character out
jp punch ;punch character out
jp reader ;reader character out
jp home ;move head to home position
jp seldsk ;select disk
jp settrk ;set track number
jp setsec ;set sector number
jp setdma ;set dma address
jp read ;read disk
jp write ;write disk
jp listst ;return list status
jp sectran ;sector translate
;;
;; Original DISKS 128 track 64 sector 4 disk
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; disk Parameter header for disk 00
dpbase:
DPE0: .dw XLT0,0x0000 ;TRANSLATE TABLE
.dw 0x0000,0x0000 ;SCRATCH AREA
.dw DIRBUF,DPB0 ;DIR BUFF,PARM BLOCK
.dw CSV0,ALV0 ;CHECK, ALLOC VECTORS
DPE1: .dw XLT1,0x0000 ;TRANSLATE TABLE
.dw 0x0000,0x0000 ;SCRATCH AREA
.dw DIRBUF,DPB1 ;DIR BUFF,PARM BLOCK
.dw CSV1,ALV1 ;CHECK, ALLOC VECTORS
DPE2: .dw XLT2,0x0000 ;TRANSLATE TABLE
.dw 0x0000,0x0000 ;SCRATCH AREA
.dw DIRBUF,DPB2 ;DIR BUFF,PARM BLOCK
.dw CSV2,ALV2 ;CHECK, ALLOC VECTORS
DPE3: .dw XLT3,0x0000 ;TRANSLATE TABLE
.dw 0x0000,0x0000 ;SCRATCH AREA
.dw DIRBUF,DPB3 ;DIR BUFF,PARM BLOCK
.dw CSV3,ALV3 ;CHECK, ALLOC VECTORS
;
; sector translate vector
; DISKDEF 0,1,64,,2048,508,128,128,1
dpblk: ;disk parameter block, common to all disks
DPB0: ;DISK PARM BLOCK
.dw 64 ;SEC PER TRACK
.db 4 ;BLOCK SHIFT
.db 15 ;BLOCK MASK
.db 0 ;EXTNT MASK
.dw 507 ;DISK SIZE-1
.dw 127 ;DIRECTORY MAX
.db 192 ;ALLOC0
.db 0 ;ALLOC1
.dw 32 ;CHECK SIZE
.dw 1 ;OFFSET
XLT0 .equ 0 ;NO XLATE TABLE
DPB1 .equ DPB0 ;.equIVALENT PARAMETERS
XLT1 .equ XLT0 ;SAME TRANSLATE TABLE
;; DISKDEF 2,0
DPB2 .equ DPB0 ;.equIVALENT PARAMETERS
XLT2 .equ XLT0 ;SAME TRANSLATE TABLE
;; DISKDEF 3,0
DPB3 .equ DPB0 ;.equIVALENT PARAMETERS
XLT3 .equ XLT0 ;SAME TRANSLATE TABLE
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; disk port and commands
lf .equ 0x0a
cr .equ 0x0d
signon: ;signon massage ??K cp/m ?.?
.db cr,lf,lf
.db MSIZE/10+"0",MSIZE % 10 +"0"
.str "K CP/M VERS "
.db VERS/10+"0",".",VERS % 10 +"0"
.db cr,lf,0
boot:
ld sp,BUFF_DEFAULT_ADDR + 0x80
call init_io
ld hl,signon
call prmsg
xor a
ld (disk_number),a
ld (old_disk_number),a
ld a,0x11
ld (IOBYTE),a
jr gocpm
wboot:
ld sp,BUFF_DEFAULT_ADDR
;reading system block (CCP+BDS)
ld hl,CCP
ld (read512_addr),hl ;system top addr (CCP)
ld hl,0x0000
ld (read512_block_no),hl ;system top sector no. (512byte read)
ld hl,0x000b
ld (read512_block),hl ;0x1600(ccp+BDOS) /512byte(sector)
call read512 ;read system block
gocpm: ;set default buff address to 0x80
ld bc,BUFF_DEFAULT_ADDR
call setdma
ld a,0xc3 ;jump wboot address set at 0x0000
ld (0x0000),a
ld hl,wboote
ld (0x0001),hl
ld (0x0005),a ;jump BDOS address set at 0x0005
ld hl,BDOS
ld (0x0006),hl
ld a,(disk_number)
ld c,a
jp cpmboot
prmsg:
ld a,(hl)
cp 0x00 ;massage end ?
ret z
ld c,a
call conout
inc hl
jr prmsg
const: in a,(UART_C)
bit 1,a
jr z,con_busy ;console status
ld a,0xff ;READY= 0xff BUSY=0x00 out Areg
ret
con_busy:
ld a,0x00
ret
reader: ;reader character out
ld a,0x1a
and 0x7f
ret
getchar:
conin: ;console character in
in a,(UART_C)
bit 1,a
jr z,getchar
in a,(UART_D)
and 0x7f
ret
list: ;list character out
ld a,c
ret
punch: ;punch character out
ld a,c
ret
conout: ;console character out
ld a,c
call putchar
ret
putchar:
push af
putchar01:
in a,(UART_C)
bit 0,a
jr z,putchar01
pop af
out (UART_D),a
ret
home:
ld c,0x00 ;track 00
call settrk
ret
listst: ;return list status
ld a,0x00
ret
sectran: ;sector translate
;logical sector > BC
;sector translate teble > de
;return to translate ogical sector > hl
; ld b,0
; ex de,hl
; add hl,bc
; ld a,(hl)
; ld (sector_number),a
; ld l,a
ld h,b
ld l,c
ret
setdma: ;set dma address set bc reg
ld h,b
ld l,c
ld (dma_Buff_addr),hl
ret
seldsk: ;c reg set disk no
ld hl,0x0000 ;err set hl=0000 return
ld a,c
cp DISKS_MAX
jr nc,disk_max
ld (disk_number),a
ld (old_disk_number),a
ld l,a
ld h,0x00
add hl,hl
add hl,hl
add hl,hl
add hl,hl
ld de,dpbase
add hl,de
ret
disk_max:
ld a,(old_disk_number)
ld (disk_number),a
ld hl,0x0000 ;err set hl=0000 return
ret
settrk: ;set track address given by c
ld hl,track_number
ld (hl),c
ret
setsec: ;set sector numbar given by c
ld hl,sector_number
ld (hl),c
ret
init_io: ;tmpz84c015 serial siob ch/pio-a ch/spi-init
call siobinit
call pioainit
call init_spi
ret
init_spi:
push af
xor a
set S_CS,a ;CS="H"
set S_DI,a ;DI="H"
out (PP2D),a
ld b,80 ;80 clok output
call loopspii
pop af
xor a
out (PP2D),a ;CS="L" DI="L" CLK="L"
call cmd0_out
cp 0x01
jp nz,init_err
call cmd8_out
cp 0x01
jp nz,init_err
call cmd55_out
cp 0x01
jp nz,init_err
call acmd41_out
call cmd58_out
ld a,(r7)
bit 7,a
jp z,init_err
bit 6,a
jr z,SD_ver2
ld hl,sdhc_msg
init_msg:
call msgout
call set_cs
ret
SD_ver2:
ld hl,sd_ver2_msg
jr init_msg
ret
init_err:
ld hl,spi_init_err_msg
call msgout
ld a,0x0d
call putchar
jp boot
cmd0_out:
ld hl,cmd0
call cmd_out
call r1_resp
ret
cmd8_out:
call dummy_data
ld hl,cmd8
call cmd_out
call r1_resp
cp 0x01
ret nz
ld b,4
ld hl,r7
cmd8_r:
call resp
ld (hl),a
inc hl
djnz cmd8_r
ld a,0x01
ret
cmd55_out:
call dummy_data
ld hl,cmd55
call cmd_out
call r1_resp
ret
acmd41_out:
call dummy_data
ld hl,acmd41 ;sd-card Initialize
call cmd_out
call r1_resp
cp 0x00
ret z
call cmd55_out
jr acmd41_out
cmd58_out:
call dummy_data
ld hl,cmd58
call cmd_out
call r1_resp
push af
ld b,4
ld hl,r7
cmd58_r:
call resp
ld (hl),a
inc hl
djnz cmd58_r
cmd58_r_d:
ld hl,r7
ld b,4
cmd58_r_d_loop:
inc hl
djnz cmd58_r_d_loop
ld a,0x0d
call putchar
pop af
ret
r1_resp:
call resp
cp 0xff
jr z,r1_resp
ret
resp:
ld d,0xff
call spi_8bit
ld a,e
ret
cmd_out: ;command out
push hl
push bc
ld b,0x06 ;command line word count
cmd_out1:
ld d,(hl) ;command line area
call spi_8bit
inc hl
djnz cmd_out1
pop bc
pop hl
ret
spi_8bit: ;outdata Dreg,inputdata Ereg
push bc
ld c,0x00
ld b,0x08
loopspi:
xor a
rlc d
rra
res S_CLK,a ;CLK L
out (PP2D),a
nop
nop
nop
nop
nop
nop
nop
nop
nop
nop
nop
nop
set S_CLK,a ;CLK H
out (PP2D),a
in a,(PP2D)
rrca
rl e
djnz loopspi
xor a
set S_DI,a ;DI H
out (PP2D),a
pop bc
ret
get_sector:
; ld a,"["
; call putchar
; ld a,(disk_number)
; call hex_a_disp
; ld a,","
; ld a,(track_number)
; call hex_a_disp
; ld a,","
; ld a,(sector_number)
; call hex_a_disp
; ld a,"="
; call putchar
ld hl,0x0000
; ld de,DISK_TRACK * DISK_SECTOR ;1 disk sector >> DISK_TRACK * DISK_SECTOR
; ld a,(disk_number)
; cp 0x00
; jr z,read_track
; ld b,a
;read_disk01:
; add hl,de
; djnz read_disk01
;disk_number * 0x2000(DISK_TRACK * DISK_SECTOR)
ld a,(disk_number)
rrca
rrca
rrca
and a,0xe0
ld h,a
read_track:
; ld de,DISK_SECTOR ;1 track sector >> DISK_SECTOR
; ld a,(track_number)
; cp 0x00
; jr z,read_sector
; ld b,a
;read_track01:
; add hl,de
; djnz read_track01
;
ld e,0x00
ld a,(track_number) ;track_number * 64
ld d,a
srl d
rr e
srl d
rr e
add hl,de
read_sector:
ld a,(sector_number)
; dec a
ld e,a
ld d,0x00
add hl,de
; ld a,h
; call hex_a_disp
; ld a,l
; call hex_a_disp
; ld a,"]"
; call putchar
ret
read: ;read next disk record(assuming disk/trk/sec/dma set)
; ld a,"R"
; call putchar
call get_sector ;read block HL reg
ld a,(r7)
bit 6,a
jp z,read_SD_ver2
ld a,h ;SDHC
ld (cmd18+03),a
ld a,l
ld (cmd18+04),a
jr spi_read2
read_SD_ver2:
ld a,h ;Ver2
ld (cmd18+02),a
ld a,l
ld (cmd18+03),a
ld hl,(dma_Buff_addr)
spi_read2:
call dummy_data ;dummy data(0xff) out
ld hl,cmd18
call cmd_out ;cmd17 Issue
call r1_resp
cp 0x00 ;response is 0x00 read mode OK?
jr nz,cmd18_err
cmd18_st:
ld d,0xff
call spi_8bit
call r1_resp ;read data start response?
cp 0xfe ;data start byte 0xfe?
jr nz, cmd18_st
ld b,0x80 ;read data size 128byte
ld hl,(dma_Buff_addr) ;read data buff address
cmd18_r:
call resp ;read data
ld (hl),a
inc hl
djnz cmd18_r
;; dummy read 128byte 2st 3st 4st
ld b,0x80 ;read data size 128byte
cmd18_r2st:
call resp
djnz cmd18_r2st
ld b,0x80
cmd18_r3st:
call resp
djnz cmd18_r3st
ld b,0x80
cmd18_r4st:
call resp
djnz cmd18_r4st
call resp ;crc Skipping read
call resp ;crc Skipping read
ld d,0xff ;dummy data 0xff
call spi_8bit
ld hl,cmd12 ;stop cmd
call cmd_out ;cmd12 Issue
ld d,0xff
call spi_8bit
call r1_resp
cp 0x00 ;response is 0x00 read mode OK?
jr nz,cmd18_err
cmd18_wch3:
call resp
cp 0x00
jr z,cmd18_wch3
call set_cs ;CS="H"
; ld a,"R"
; call putchar
; ld a,"o"
; call putchar
; ld a,"k"
; call putchar
; ld a,0x0d
; call putchar
xor a
ret
cmd18_err:
call set_cs ;CS="H"
ld a,0x01
ret
read512:
;read 1sector 512byte
ld hl,(read512_block_no) ;read bolck_no
ld a,(r7)
bit 6,a
jp z,read512_SD_ver2
ld a,h ;SDHC
ld (cmd18+03),a
ld a,l
ld (cmd18+04),a
jr spi_read512_2
read512_SD_ver2:
ld a,h ;Ver2
ld (cmd18+02),a
ld a,l
ld (cmd18+03),a
spi_read512_2:
call dummy_data ;dummy data(0xff) out
ld hl,cmd18
call cmd_out ;cmd17 Issue
call r1_resp
cp 0x00 ;response is 0x00 read mode OK?
jr nz,cmd18_512_err
sector_read_loop:
cmd18_512_st:
call r1_resp ;read data start response?
cp 0xfe ;data start byte 0xfe?
jr nz, cmd18_512_st
ld hl,(read512_addr) ;read data buff address
ld b,0x00 ;read data size 256byte
cmd18_512_r:
call resp ;read data
ld (hl),a
inc hl
djnz cmd18_512_r
ld b,0x00 ;2st 256byte write
cmd18_512_r2st:
call resp
ld (hl),a ;read data
inc hl
djnz cmd18_512_r2st
ld (read512_addr),hl
call resp ;crc Skipping read
call resp ;crc Skipping read
ld hl,(read512_block)
dec hl
ld (read512_block),hl
ld a,h ;HL = 0?
or l
jr nz,sector_read_loop
ld d,0xff ;dummy data 0xff(cs low)
call spi_8bit
ld hl,cmd12 ;stop cmd
call cmd_out ;cmd12 Issue
ld d,0xff
call spi_8bit
call r1_resp
cp 0x00 ;response is 0x00 read mode OK?
jr nz,cmd18_512_err
cmd18_512_wch3:
call resp
cp 0x00
jr z,cmd18_512_wch3
call set_cs ;CS="H"
xor a
ret
cmd18_512_err:
call set_cs ;CS="H"
ld a,0x01
ret
write:
; ld a,"W"
; call putchar
call get_sector
spi_write1:
ld a,(r7)
bit 6,a
jp z,write_SD_ver2
ld a,h ;SDHC
ld (cmd25+03),a
ld a,l
ld (cmd25+04),a
jr spi_write2
write_SD_ver2: ;Ver2
ld a,h
ld (cmd25+02),a
ld a,l
ld (cmd25+03),a
spi_write2:
; call dummy_data
ld hl,cmd25
call cmd_out
call r1_resp
cp 0x00
jp nz,cmd25_err
ld d,0xff
call spi_8bit
ld d,0xfc ;cmd25 data token
call spi_8bit
ld hl,(dma_Buff_addr)
ld b,0x80
cmd25_w:
ld d,(hl)
inc hl
call spi_8bit
djnz cmd25_w
; 2st dummy write(0xe5)
ld b,0x80
cmd25_w2st:
ld d,0xe5
call spi_8bit
djnz cmd25_w2st
; 3st dummy write(0xe5)
ld b,0x80
cmd25_w3st:
ld d,0xe5
call spi_8bit
djnz cmd25_w3st
; 4st dummy write(0xe5)
ld b,0x80
cmd25_w4st:
ld d,0xe5
call spi_8bit
djnz cmd25_w4st
ld d,0xff
call spi_8bit ;crc
ld d,0xff
call spi_8bit ;crc
call r1_resp
and 0x0f
cp 0x05
jr nz,cmd25_err2
cmd25_wch:
call resp
cp 0x00
jr z,cmd25_wch
ld d,0xfd ;cmd25 stop token
call spi_8bit
ld d,0xff
call spi_8bit
cmd25_wch3:
call resp
cp 0x00
jr z,cmd25_wch3
call set_cs ;set CS
call dummy_data
; ld a,"W"
; call putchar
; ld a,"o"
; call putchar
; ld a,"k"
; call putchar
; ld a,0x0d
; call putchar
xor a
ret
cmd25_err:
cmd25_err2:
call set_cs ;set cs
ld a,0x01
ret
set_cs:
xor a
set S_CS,a ;CS="H"
set S_DI,a ;DI="H"
out (PP2D),a
ret
dummy_data:
xor a
set S_CS,a ;CS="H"
set S_DI,a ;DI="H"
out (PP2D),a
ld b,8 ;1clok output
call loopspii
xor a
set S_CS,a ;CS="H"
set S_DI,a ;DI="H"
out (PP2D),a
ret
loopspii:
res S_CLK,a ;CLK L
out (PP2D),a
nop
nop
nop
nop
nop
nop
nop
nop
set S_CLK,a ;CLK H
out (PP2D),a
nop
nop
nop
nop
nop
djnz loopspii
ret
msgout:
ld a,(hl) ;(HL)reg is output disp at 0x00
cp 0x00
ret z
call putchar
inc hl
jr msgout
siobinit:
ld a,0b00000001 ;RxC,TxC Port set
out (SCR0),a
xor a
out (UART_C),a
out (UART_C),a
out (UART_C),a
ld a,0b01000000 ;soft reset
out (UART_C),a
ld a,0b01001110 ;8bit NonParity 1StopBit 1/16Portrait
out (UART_C),a
ld a,0b00000101 ;Rx or Tx Enable
out (UART_C),a
ret
pioainit:
ld a,0b00000010 ;Parallel port B 2x P0-P3 input P4-P7 OutPut Mode
out (PPBC),a
ret
hl_disp:
push hl
ld a,(HL) ;dump addres data (HL)
inc HL
call hex_a_disp
ld a,(HL) ;dump addres data (HL)
call hex_a_disp
pop hl
ret
hex_a_disp: ;Areg(HEX) >> putchar(areg)
push af
rrca ;7-4bit Right shift
rrca
rrca
rrca
call hex_ascii ;3-0bit Hex >> Hex ascii(0-F)
call putchar ;7-4bit putchar
pop af
call hex_ascii ;3-0bit Hex >> Hex ascii(0-F)
call putchar ;3-0bit putchar
ret
hex_ascii: ;Areg(HEX) >> Areg(ascii code)
and a,0x0f
cp 0x0a
jr c,ascii0_9
add 0x37
ret
ascii0_9:
add 0x30
ret
sdhc_msg:
.str ":SDHC"
.db 0x0d
.db 0x00
sd_ver2_msg:
.str ":SD Ver2"
.db 0x0d
.db 0x00
spi_init_err_msg:
.str "Spi Init Err"
.db 0x0d
.db 0x00
cmd0: ;;48bit(6byte) Fixed length
.db 0x40 ;;command index
.db 0x00 ;;argument
.db 0x00 ;;argument
.db 0x00 ;;argument
.db 0x00 ;;argument
.db 0x95 ;;CRC
cmd8:
.db 0x48
.db 0x00
.db 0x00
.db 0x01
.db 0xaa
.db 0x87
cmd55:
.db 0x77
.db 0x00
.db 0x00
.db 0x00
.db 0x00
.db 0xff
acmd41:
.db 0x69
.db 0x40
.db 0xff
.db 0x80
.db 0x00
.db 0xff
cmd58:
.db 0x7a
.db 0x00
.db 0x00
.db 0x00
.db 0x00
.db 0xff
cmd16:
.db 0x50
.db 0x00
.db 0x00
.db 0x02
.db 0x00
.db 0xff
cmd18:
.db 0x52
.db 0x00
.db 0x00
.db 0x00
.db 0x00
.db 0xff
cmd12:
.db 0x4c
.db 0x00
.db 0x00
.db 0x00
.db 0x00
.db 0xff
cmd25:
.db 0x59
.db 0x00
.db 0x00
.db 0x00
.db 0x00
.db 0xff
r7:
.ds 4
; scratch ram area for bdos use
;begdat equ $ ;beginning of data area
DIRBUF: .ds 128 ;DIRECTORY ACCESS BUFFER
ALV0: .ds 64
CSV0: .ds 32
ALV1: .ds 64
CSV1: .ds 32
ALV2: .ds 64
CSV2: .ds 32
ALV3: .ds 64
CSV3: .ds 32
dma_Buff_addr: .dw BUFF_DEFAULT_ADDR ;dma buff address
sector_number: .db 0x01 ;sector number
track_number: .db TRACK_OFFSET ;track number
disk_number: .db 0x00 ;disk number
old_disk_number: .dw 0x00 ;old disk number
read512_addr: .dw 0xdc00 ;system top addr(512byte read)
read512_block_no: .dw 0x0000 ;system top sector no. (512byte read)
read512_block: .dw 0x000b ;0x1600(ccp+BDOS) /512byte(sector)
.end
BIOSのHEXファイル
:20F20000C399F2C3B3F2C3F7F2C308F3C317F3C313F3C315F3C303F3C327F3C339F3C35DC8
:20F22000F3C362F3C333F3C3A6F4C3B8F5C32DF3C330F300000000000000002CF773F2ECD0
:20F24000F7ACF700000000000000002CF773F24CF80CF800000000000000002CF773F2AC10
:20F26000F86CF800000000000000002CF773F20CF9CCF84000040F00FB017F00C000200033
:20F2800001000D0A0A36324B2043502F4D205645525320322E320D0A00310001CD67F321C7
:20F2A00082F2CDECF2AF3230F93231F93E1132030018183180002100DC2233F921000022D6
:20F2C00035F9210B002237F9CD32F5018000CD33F33EC33200002103F22201003205002156
:20F2E00006E42206003A30F94FC300DC7EFE00C84FCD17F32318F5DB39CB4F28033EFFC9B2
:20F300003E00C93E1AE67FC9DB39CB4F28FADB38E67FC979C979C979CD1CF3C9F5DB39CB59
:20F320004728FAF1D338C90E00CD5DF3C93E00C96069C96069222CF9C921000079FE04306D
:20F34000123230F93231F96F2600292929291133F219C93A31F93230F9210000C9212FF9A1
:20F3600071C9212EF971C9CD8BF6CDA3F6CD71F3C9F5AFCBF7CBFFD3300650CD69F6F1AFCE
:20F38000D330CDCAF3FE01C2BCF3CDD4F3FE01C2BCF3CDF2F3FE01C2BCF3CDFFF3CD13F4B7
:20F3A0003A28F7CB7FCABCF3CB77280A21D3F6CD81F6CD4DF6C921DAF618F4C921E4F6CD28
:20F3C00081F63E0DCD1CF3C399F221F2F6CD4AF4CD3BF4C9CD55F621F8F6CD4AF4CD3BF43A
:20F3E000FE01C006042128F7CD43F4772310F93E01C9CD55F621FEF6CD4AF4CD3BF4C9CD8B
:20F4000055F62104F7CD4AF4CD3BF4FE00C8CDF2F318ECCD55F6210AF7CD4AF4CD3BF4F5CC
:20F4200006042128F7CD43F4772310F92128F706042310FD3E0DCD1CF3F1C9CD43F4FEFF7F
:20F4400028F9C916FFCD58F47BC9E5C5060656CD58F42310F9C1E1C9C50E000608AFCB0237
:20F460001FCBAFD330000000000000000000000000CBEFD330DB300FCB1310E1AFCBFFD3FE
:20F4800030C1C92100003A30F90F0F0FE6E0671E003A2FF957CB3ACB1BCB3ACB1B193A2EA6
:20F4A000F95F160019C9CD83F43A28F7CB77CABBF47C3219F77D321AF7180B7C3218F77DC9
:20F4C0003219F72A2CF9CD55F62116F7CD4AF4CD3BF4FE00205616FFCD58F4CD3BF4FEFEB4
:20F4E00020F406802A2CF9CD43F4772310F90680CD43F410FB0680CD43F410FB0680CD43BC
:20F50000F410FBCD43F4CD43F416FFCD58F4211CF7CD4AF416FFCD58F4CD3BF4FE00200C23
:20F52000CD43F4FE0028F9CD4DF6AFC9CD4DF63E01C92A35F93A28F7CB77CA47F57C321948
:20F54000F77D321AF718087C3218F77D3219F7CD55F62116F7CD4AF4CD3BF4FE002053CDCD
:20F560003BF4FEFE20F92A33F90600CD43F4772310F90600CD43F4772310F92233F9CD4339
:20F58000F4CD43F42A37F92B2237F97CB520D016FFCD58F4211CF7CD4AF416FFCD58F4CD13
:20F5A0003BF4FE00200CCD43F4FE0028F9CD4DF6AFC9CD4DF63E01C9CD83F43A28F7CB7750
:20F5C000CACDF57C3225F77D3226F718087C3224F77D3225F72122F7CD4AF4CD3BF4FE0016
:20F5E000C247F616FFCD58F416FCCD58F42A2CF906805623CD58F410F9068016E5CD58F4A9
:20F6000010F9068016E5CD58F410F9068016E5CD58F410F916FFCD58F416FFCD58F4CD3B37
:20F62000F4E60FFE052020CD43F4FE0028F916FDCD58F416FFCD58F4CD43F4FE0028F9CD31
:20F640004DF6CD55F6AFC9CD4DF63E01C9AFCBF7CBFFD330C9AFCBF7CBFFD3300608CD6936
:20F66000F6AFCBF7CBFFD330C9CBAFD3300000000000000000CBEFD330000000000010E95A
:20F68000C97EFE00C8CD1CF32318F63E01D33AAFD339D339D3393E40D3393E4ED3393E05CC
:20F6A000D339C93E02D333C9E57E23CDB4F67ECDB4F6E1C9F50F0F0F0FCDC7F6CD1CF3F142
:20F6C000CDC7F6CD1CF3C9E60FFE0A3803C637C9C630C93A534448430D003A534420566529
:20F6E00072320D0053706920496E6974204572720D0040000000009548000001AA8777005D
:20F70000000000FF6940FF8000FF7A00000000FF5000000200FF5200000000FF4C0000005C
:08F7200000FF5900000000FF8A
:0DF92C008000010100000000DC00000B0065
:00000001FF
KL5C80_cpm_rwのソース
;z80 (KL5C80B12) cp/m V2.2 system read/write by Pinecone 2020/11/19
; KL5C80B12 cpu
; ram 0000h -- ffffh
; clock 10MHz(ext.clock 20MHz)
; KL5C80B12 serial communication
; extemal Clock 614.4KHz(4.9152MHz TC74HC4040 1/8 Frequency division)
; Band Rate:38400 8bits 1Stopbits none Parity (81N)
; assembler
; program start 0x8000
; main 0x8000
;
; assemblers ASxxxx and ASlink V5.10
; file name KL5C80_cpm_rw.asm
; $ asz80 -l -s -o KL5C80_cpm_rw.asm
; $ aslink -i KL5C80_cpm_rw
; $ monitor l command Hex load jump 0x8000
.z80
;;KL5C80B12 System control register
SCR0 .equ 0x3a
SCR1 .equ 0x3b
;;KL5C80 UART
UART_D .equ 0x38
UART_C .equ 0x39
;;KL5C80 Parallel port B
PP2D .equ 0x30
PP3D .equ 0x31
PP4D .equ 0x32
PPBC .equ 0x33
;OUTPUT-PORT
S_DI .equ 7 ;0b10000000 D7
S_CS .equ 6 ;0b01000000 D6
S_CLK .equ 5 ;0b00100000 D5
;INPUT-PORT
DO .equ 0 ;0b00000001 D0
.area FORMAT(ABS)
.org 0x8000
; spi read, write. boot
;
;
start:
call siobinit
call piobinit
call init_spi
ld hl,rwg_msg
call msgout
call getchar
call putchar
cp "r"
jr z,read
cp "w"
jr z,write
cp "b"
jr z,cpm_boot
ret
read:
call cr
call spi_read
ret
write:
call cr
call spi_write
ret
cpm_boot:
ld hl,0x0000 ;CP/M system block 0x0000 start
ld (rw_block_no),hl
ld hl,0x000b ;ccp+bdos >0x0b
ld (rw_block),hl
ld hl,0xdc00 ;62K cp/m ccp top addr >> 0xdc00
ld (rw_addr),hl
call spi_read_go
ld hl,0x000b ;CP/M bios block 0x000b start
ld (rw_block_no),hl
ld hl,0x0004 ;bios >0x04
ld (rw_block),hl
ld hl,0xf200 ;62K cp/m bios top addr >> 0xf200
ld (rw_addr),hl
call spi_read_go
ld hl,cpm_boot_msg
call msgout
jp 0xf200
init_spi:
push af
xor a
set S_CS,a ;CS="H"
set S_DI,a ;DI="H"
out (PP2D),a
ld b,80 ;80 clok output
call loopspii
pop af
xor a
out (PP2D),a ;CS="L" DI="L" CLK="L"
call cmd0_out
cp 0x01
jp nz,init_err
call cmd8_out
cp 0x01
jp nz,init_err
call cmd55_out
cp 0x01
jp nz,init_err
call acmd41_out
call cmd58_out
ld a,(r7)
bit 7,a
jp z,init_err
bit 6,a
jr z,SD_ver2
ld hl,sdhc_msg
init_msg:
call msgout
call set_cs
ret
SD_ver2:
ld hl,sd_ver2_msg
jr init_msg
init_err:
ld hl,spi_init_err_msg
call msgout
ld a,0x0d
call putchar
jp 0x0000
set_cs:
xor a
set S_CS,a ;CS="H"
set S_DI,a ;DI="H"
out (PP2D),a
ret
cmd0_out:
ld hl,cmd0
call cmd_out
call r1_resp
ret
cmd8_out:
call dummy_data
ld hl,cmd8
call cmd_out
call r1_resp
cp 0x01
ret nz
ld b,4
ld hl,r7
cmd8_r:
call resp
ld (hl),a
inc hl
djnz cmd8_r
ld a,0x01
ret
cmd55_out:
call dummy_data
ld hl,cmd55
call cmd_out
call r1_resp
ret
acmd41_out:
call dummy_data
ld hl,acmd41 ;sd-card Initialize
call cmd_out
call r1_resp
cp 0x00
ret z
call cmd55_out
jr acmd41_out
cmd58_out:
call dummy_data
ld hl,cmd58
call cmd_out
call r1_resp
push af
ld b,4
ld hl,r7
cmd58_r:
call resp
ld (hl),a
inc hl
djnz cmd58_r
cmd58_r_d:
ld hl,r7
ld b,4
cmd58_r_d_loop:
inc hl
djnz cmd58_r_d_loop
ld a,0x0d
call putchar
pop af
ret
cr:
ld a,0x0d
call putchar
ret
spi_read:
call data_in
cp 0x00
ret z
ld hl,yes_msg
call msgout
call getchar
cp "y"
ret nz
call spi_read_go
call cr
ret
spi_write:
call data_in
cp 0x00
ret z
ld hl,yes_msg
call msgout
call getchar
cp "y"
ret nz
call spi_write_go
ret
data_in:
call cr
ld hl,rw_sblock_no_msg
call msgout
call input_hl
cp 0x00
jr z,spi_data_in01
call cr
xor a
ret
spi_data_in01: ;read/write block no
call cr
ld (rw_block_no),hl
ld hl,rw_block_msg
call msgout
call input_hl
cp 0x00
jr z,spi_data_in02
call cr
xor a
ret
spi_data_in02:
call cr
ld (rw_block),hl ;read/write block
ld hl,rw_addr_msg
call msgout
call input_hl
cp 0x00
jr z,spi_data_in03
call cr
xor a
ret
spi_data_in03:
call cr
ld (rw_addr),hl ;read/write addr
ld a,0xff
ret
spi_write_go:
ld hl,(rw_block_no)
ld a,(r7)
bit 6,a
jp z,write_SD_ver2
ld a,h ;SDHC
ld (cmd25+03),a
ld a,l
ld (cmd25+04),a
jr spi_write4
write_SD_ver2: ;Ver2
ld a,h
ld (cmd25+02),a
ld a,l
ld (cmd25+03),a
spi_write4:
call dummy_data
ld hl,cmd25
call cmd_out
call r1_resp
cp 0x00
jp nz,cmd25_err
ld d,0xff
call spi_8bit
sector_write_loop:
ld hl,(rw_addr)
ld d,0xfc ;cmd25 data token
call spi_8bit
;; spi write 256byte 1st blok
ld b,0x00
cmd25_w: ;1st 256byte write
ld d,(hl)
inc hl
call spi_8bit ; D reg >> write data
djnz cmd25_w
; 2st write 256byte 1st blok
ld b,0x00
cmd25_w2st: ;2st 256byte write
ld d,(hl)
inc hl
call spi_8bit ; D reg >> write data
djnz cmd25_w2st
ld (rw_addr),hl
ld d,0xff
call spi_8bit ;crc
ld d,0xff
call spi_8bit ;crc
call r1_resp
and 0x0f
cp 0x05
jr nz,cmd25_err2
cmd25_wch:
call resp
cp 0x00
jr z,cmd25_wch
ld d,0xff
call spi_8bit
ld hl,(rw_block)
dec hl
ld (rw_block),hl
ld a,h ;HL = 0?
or l
jr nz,sector_write_loop
ld d,0xfd ;cmd25 stop token
call spi_8bit
ld d,0xff
call spi_8bit
cmd25_wch2:
call resp
cp 0x00
jr z,cmd25_wch2
call dummy_data
call set_cs ;set CS
ld hl,rw_ok_msg
call msgout
call cr
xor a
ret
cmd25_err:
cmd25_err2:
ld hl,cmd25_err_msg
call msgout
call set_cs ;set CS
ld a,0x01
ret
spi_read_go:
ld hl,(rw_block_no)
ld a,(r7)
bit 6,a
jp z,read_SD_ver2
ld a,h ;SDHC
ld (cmd18+03),a
ld a,l
ld (cmd18+04),a
jr spi_read01
read_SD_ver2: ;Ver2
ld a,h
ld (cmd18+02),a
ld a,l
ld (cmd18+03),a
spi_read01:
call dummy_data
ld hl,cmd18
call cmd_out
call r1_resp
cp 0x00
jp nz,cmd18_err
sector_read_loop:
cmd18_st:
call r1_resp ;read data start response?
cp 0xfe ;data start byte 0xfe?
jr nz, cmd18_st
ld hl,(rw_addr)
ld b,0x00
cmd18_r:
call resp ;read data
ld (hl),a
inc hl
djnz cmd18_r
; 2st dummy read
ld b,0x00
cmd18_r2st: ;2st 256byte write
call resp
ld (hl),a
inc hl
djnz cmd18_r2st
ld (rw_addr),hl
call resp ;crc Skipping read
call resp ;crc Skipping read
ld hl,(rw_block)
dec hl
ld (rw_block),hl
ld a,h ;HL = 0?
or l
jr nz,sector_read_loop
ld d,0xff ;dummy data 0xff(cs low)
call spi_8bit
ld hl,cmd12 ;stop cmd
call cmd_out ;cmd12 Issue
ld d,0xff
call spi_8bit
call r1_resp
cp 0x00 ;response is 0x00 read mode OK?
jr nz,cmd18_err
cmd18_wch:
call resp
cp 0x00
jr z,cmd18_wch
call set_cs
xor a
ret
;; 1 sector write
cmd18_err:
cmd18_err2:
ld hl,cmd25_err_msg
call msgout
call set_cs
ld a,0x01
ret
;**************************************************
cmd_out: ;command out
push hl
push bc
ld b,0x06 ;command line word count
cmd_out1:
ld d,(hl) ;command line area
call spi_8bit
inc hl
djnz cmd_out1
pop bc
pop hl
ret
r1_resp:
call resp
cp 0xff
jr z,r1_resp
ret
resp:
ld d,0xff
call spi_8bit
ld a,e
ret
cmd0_msg:
.str "CMD0:"
.db 0x00
dummy_data:
xor a
set S_CS,a ;CS="H"
set S_DI,a ;DI="H"
out (PP2D),a
ld b,8 ;1clok output
call loopspii
xor a
set S_CS,a ;CS="H"
set S_DI,a ;DI="H"
out (PP2D),a
ret
loopspii:
res S_CLK,a ;CLK L
out (PP2D),a
nop
nop
nop
nop
nop
nop
nop
nop
set S_CLK,a ;CLK H
out (PP2D),a
nop
nop
nop
nop
nop
djnz loopspii
ret
spi_8bit: ;outdata Dreg,inputdata Ereg
push bc
ld c,0x00
ld b,0x08
loopspi:
xor a
rlc d
rra
res S_CLK,a ;CLK L
out (PP2D),a
nop
nop
nop
nop
nop
nop
set S_CLK,a ;CLK H
out (PP2D),a
in a,(PP2D)
rrca
rl e
djnz loopspi
xor a
set S_DI,a ;DI H
out (PP2D),a
pop bc
ret
msgout:
ld a,(hl) ;(HL)reg is output disp at 0x00
cp 0x00
ret z
call putchar
inc hl
jr msgout
hex_a_disp: ;Areg(HEX) >> putchar(areg)
push af
rrca ;7-4bit Right shift
rrca
rrca
rrca
call hex_ascii ;3-0bit Hex >> Hex ascii(0-F)
call putchar ;7-4bit putchar
pop af
call hex_ascii ;3-0bit Hex >> Hex ascii(0-F)
call putchar ;3-0bit putchar
ret
hex_ascii: ;Areg(HEX) >> Areg(ascii code)
and a,0x0f
cp 0x0a
jr c,ascii0_9
add 0x37
ret
ascii0_9:
add 0x30
ret
input_l: ;input Lreg hex (1byte)
push bc
ld b,0x02
jr input_loop
input_hl: ;input HLreg hex (2byte)
push bc
ld b,0x04
input_loop:
ld hl,0x0000 ;HL reg cler
jr input_hl2
shift_hl:
add hl,hl ;HL reg shift left 4bit
add hl,hl
add hl,hl
add hl,hl
input_hl2:
call getchar ;input ascii hex 1char
call putchar
call ascii_hex ;ascii hex 1char >> Areg
cp 0xff
jr z,input_hl_err
and 0x0f ;Areg low order 4bit >> Lreg
or l
ld l,a
djnz shift_hl
input_hl_end:
pop bc
xor a ;OK >> Areg 0x00
ret
input_hl_err:
ld a,0xff ;NG >> Areg 0xff
pop bc
ret
getchar:in a,(UART_C)
bit 1,a
jr z,getchar
in a,(UART_D)
ret
putchar:push af
putchar01:
in a,(UART_C)
bit 0,a
jr z,putchar01
pop af
out (UART_D),a
ret
ascii_hex:
sub 0x30
jr c,err_hex
cp 0x0A ;0-9
jr c,hex_1_9
sub 0x11
cp 0x06 ;A-F
jr c,hex_A_F
sub 0x20
cp 0x06 ;a-f
jr nc,err_hex
hex_A_F:
add 0x0a
hex_1_9:
ret
err_hex:ld a,0xff
ret
siobinit:
ld a,0b00000001 ;RxC,TxC Port set
out (SCR0),a
xor a
out (UART_C),a
out (UART_C),a
out (UART_C),a
ld a,0b01000000 ;soft reset
out (UART_C),a
ld a,0b01001110 ;8bit NonParity 1StopBit 1/16Portrait
out (UART_C),a
ld a,0b00000101 ;Rx or Tx Enable
out (UART_C),a
ret
piobinit:
ld a,0b00000010 ;Parallel port B 2x P0-P3 input P4-P7 OutPut Mode
out (PPBC),a
ret
sdhc_msg:
.str ":SDHC"
.db 0x0d
.db 0x00
sd_ver2_msg:
.str ":SD Ver2"
.db 0x0d
.db 0x00
spi_init_err_msg:
.str "Spi Init Err"
.db 0x0d
.db 0x00
cmd17_err_msg:
.str "cmd17 Err"
.db 0x0d
.db 0x00
cmd24_err_msg:
.str "cmd24 Err"
.db 0x0d
.db 0x00
cmd25_err_msg:
.str "cmd25 Err"
.db 0x0d
.db 0x00
rw_sblock_no_msg:
.str " read/write start block No:"
.db 0x00
rw_block_msg:
.str " read/write block:"
.db 0x00
rw_addr_msg:
.str " read/write addr:"
.db 0x00
yes_msg:
.str " Yes:"
.db 0x00
rw_ok_msg:
.str " read/write ok!"
.db 0x00
rwg_msg:
.str " read >> r :write >> w CP/M boot >> b key in:"
.db 0x00
cpm_boot_msg:
.db 0x0d
.str " CP/M system boot !"
.db 0x0d
.db 0x00
cmd0: ;;48bit(6byte) Fixed length
.db 0x40 ;;command index
.db 0x00 ;;argument
.db 0x00 ;;argument
.db 0x00 ;;argument
.db 0x00 ;;argument
.db 0x95 ;;CRC
cmd8:
.db 0x48
.db 0x00
.db 0x00
.db 0x01
.db 0xaa
.db 0x87
cmd55:
.db 0x77
.db 0x00
.db 0x00
.db 0x00
.db 0x00
.db 0xff
acmd41:
.db 0x69
.db 0x40
.db 0xff
.db 0x80
.db 0x00
.db 0xff
cmd58:
.db 0x7a
.db 0x00
.db 0x00
.db 0x00
.db 0x00
.db 0xff
cmd16:
.db 0x50
.db 0x00
.db 0x00
.db 0x02
.db 0x00
.db 0xff
cmd17:
.db 0x51
.db 0x00
.db 0x00
.db 0x02
.db 0x00
.db 0xff
cmd18:
.db 0x52
.db 0x00
.db 0x00
.db 0x00
.db 0x00
.db 0xff
cmd12:
.db 0x4c
.db 0x00
.db 0x00
.db 0x00
.db 0x00
.db 0xff
cmd23:
.db 0x57
.db 0x00
.db 0x00
.db 0x00
.db 0x00
.db 0xff
cmd24:
.db 0x58
.db 0x00
.db 0x00
.db 0x00
.db 0x00
.db 0xff
cmd25:
.db 0x59
.db 0x00
.db 0x00
.db 0x00
.db 0x00
.db 0xff
r7:
.ds 4
rw_block_no:
.ds 2
rw_block:
.ds 2
rw_addr:
.ds 2
.end
KL5C80_cpm_rwのHEXファイル
:20800000CDE283CDFA83CD6380219684CD6083CDB483CDBD83FE722809FE77280CFE622866
:208020000FC9CD3481CD3A81C9CD3481CD5381C9210000222785210B002229852100DC229F
:208040002B85CD5F82210B002227852104002229852100F2222B85CD5F8221C584CD608326
:20806000C300F2F5AFCBF7CBFFD3300650CD2383F1AFD330CDC380FE01C2AD80CDCD80FE96
:2080800001C2AD80CDEB80FE01C2AD80CDF880CD0C813A2385CB7FCAAD80CB77280A21FF74
:2080A00083CD6083CDBB80C921068418F4211084CD60833E0DCDBD83C30000AFCBF7CBFF4A
:2080C000D330C921DB84CDEC82CDFA82C9CD0F8321E184CDEC82CDFA82FE01C00604212391
:2080E00085CD0283772310F93E01C9CD0F8321E784CDEC82CDFA82C9CD0F8321ED84CDEC1C
:2081000082CDFA82FE00C8CDEB8018ECCD0F8321F384CDEC82CDFA82F50604212385CD0280
:2081200083772310F921238506042310FD3E0DCDBD83F1C93E0DCDBD83C9CD6981FE00C866
:20814000218084CD6083CDB483FE79C0CD5F82CD3481C9CD6981FE00C8218084CD6083CDF7
:20816000B483FE79C0CDB781C9CD3481213F84CD6083CD8E83FE002805CD3481AFC9CD34A9
:2081800081222785215B84CD6083CD8E83FE002805CD3481AFC9CD3481222985216E84CDAB
:2081A0006083CD8E83FE002805CD3481AFC9CD3481222B853EFFC92A27853A2385CB77CABB
:2081C000CC817C3220857D32218518087C321F857D322085CD0F83211D85CDEC82CDFA823E
:2081E000FE00C2538216FFCD3B832A2B8516FCCD3B8306005623CD3B8310F906005623CD74
:208200003B8310F9222B8516FFCD3B8316FFCD3B83CDFA82E60FFE052039CD0283FE002873
:20822000F916FFCD3B832A29852B2229857CB520B916FDCD3B8316FFCD3B83CD0283FE003A
:2082400028F9CD0F83CDBB80218684CD6083CD3481AFC9213484CD6083CDBB803E01C92AFE
:2082600027853A2385CB77CA74827C3208857D32098518087C3207857D320885CD0F8321E0
:208280000585CDEC82CDFA82FE00C2E082CDFA82FEFE20F92A2B850600CD0283772310F97B
:2082A0000600CD0283772310F9222B85CD0283CD02832A29852B2229857CB520D016FFCD77
:2082C0003B83210B85CDEC8216FFCD3B83CDFA82FE00200CCD0283FE0028F9CDBB80AFC9F0
:2082E000213484CD6083CDBB803E01C9E5C5060656CD3B832310F9C1E1C9CD0283FEFF2840
:20830000F9C916FFCD3B837BC9434D44303A00AFCBF7CBFFD3300608CD2383AFCBF7CBFF7F
:20832000D330C9CBAFD3300000000000000000CBEFD330000000000010E9C9C50E00060894
:20834000AFCB021FCBAFD330000000000000CBEFD330DB300FCB1310E7AFCBFFD330C1C953
:208360007EFE00C8CDBD832318F6F50F0F0F0FCD7D83CDBD83F1CD7D83CDBD83C9E60FFEE9
:208380000A3803C637C9C630C9C506021803C50604210000180429292929CDB483CDBD836A
:2083A000CDC883FEFF2809E60FB56F10E9C1AFC93EFFC1C9DB39CB4F28FADB38C9F5DB3930
:2083C000CB4728FAF1D338C9D6303813FE0A380ED611FE063806D620FE063003C60AC93ED8
:2083E000FFC93E01D33AAFD339D339D3393E40D3393E4ED3393E05D339C93E02D333C93A13
:20840000534448430D003A534420566572320D0053706920496E6974204572720D00636DCA
:20842000643137204572720D00636D643234204572720D00636D643235204572720D002019
:20844000726561642F777269746520737461727420626C6F636B204E6F3A002072656164DA
:208460002F777269746520626C6F636B3A0020726561642F777269746520616464723A0032
:20848000205965733A0020726561642F7772697465206F6B21002072656164203E3E207236
:2084A000203A7772697465203E3E2077202043502F4D20626F6F74203E3E2062206B65795A
:2084C00020696E3A000D2043502F4D2073797374656D20626F6F7420210D00400000000008
:2084E0009548000001AA877700000000FF6940FF8000FF7A00000000FF5000000200FF51B5
:2085000000000200FF5200000000FF4C00000000FF5700000000FF5800000000FF590000B8
:038520000000FF59
:00000001FF