今回は、ROMをRAMに切り替えRAM64Kbyteになるか確認をしたいと思います。
確認手順として、0xa000から起動するモニタを作成して、「最初のモニタ」で0x8000から配置したRAM上でこのモニタを起動します。
起動したモニタで i/oアドレスの0x80に0x03を設定して、ROMからRAMに切り替えます。その状態で、0x0000が書き換えられるか確認します。
まずは、0xa000から起動するモニタを作成します。
前回の「最初のモニタ」の開始アドレスの変更と、モニタ上で起動するので、スタックポインタと８２５１の初期化をコメントアウトして無効にします。
.org 0xa000
jp start
.org 0xa100
start: ;cold start
; ld sp,0x0000 ;stack pointer set
; call com_init ;serial channel initialize
ld hl,msg_op ;opening message display
call msgout
prompt: ld a,">" ;main routine「最初のモニタ」でｌコマンド（HEX ｆｉｌｅ LOAD）で0xa000から始まるモニタを読み込みます。
jコマンドで 0xa000にジャンプして、モニタを起動します。
iコマンドで、i/oアドレスの0x80の内容を 0x03に変更します。（ROMからRAMへ切り替わり、切り替え表示のLEDがRAM側に点灯します。）
mコマンドで0x0000の内容を任意の値に変更できるか確認します
Monitor Z80+8251+8255 ver0.71 by Pinecone 2020/09/01
>?
? Help
d MemoryDump
m MemoryChange
l HexFileLoad
j jump
i I/oRegister
c Call
>l
03A00000C300A1F9
・
中略
・
00000001FF
OK
>
>j a000 y:
Monitor Z80+8251+8255 (0xa000) ver0.71 by Pinecone 2020/09/03
>?
? Help
d MemoryDump
m MemoryChange
l HexFileLoad
j jump
i I/oRegister
c Call
>i 80 78 03
>m 0000 AD 00
>m 0000 00
>ちゃんと 0x0000の内容を変更できたみたいです。
次回は、RAM６４Kに切り替えるｔコマンドと、SDCARDのブロック読み書きのコマンドを追加したいと思います。
以下 0xa000から起動できるモニタソースです。
; Z80+8251+8255 monitor(0xa0000) ver0.71 by Pinecone 2020/09/03
;
; Z80 cpu
; rom 0000h -- 7fffh
; ram 8000h -- ffffh
; External clock 4.9142MHz
; 8251 serial communication
; extemal Clock 0.6144MHz (4.9152MHz TC74HC4040 1/8 Frequency division)
; Band Rate:38400 8bits 1Stopbits none Parity (81N)
; assembler
; program start a000H
; main a100H
;
; assemblers ASxxxx and ASlink V5.10
; file name Z80_8251_moni_a000.asm
; $ asz80 -l -s -o Z80_8251_moni_a000.asm
; $ aslink -i Z80_8251_moni_a000
; windows10 rom-writer TL866-2 plus Z80_8251_moni_a000.ihx
;
.z80
.area TEST(ABS)
USARTD .equ 0x84 ;USART DATA REG
USARTC .equ 0x85 ;USART CONTL REG
PPIA .equ 0x88 ;PPI-A PORT DATA REG
PPIB .equ 0x89 ;PPI-B PORT DATA REG
PPIC .equ 0x8a ;PPI-C PORT DATA REG
PPICNT .equ 0x8b ;PPI CONTL REG
.org 0xa000
jp start
.org 0xa100
start: ;cold start
; ld sp,0x0000 ;stack pointer set
; call com_init ;serial channel initialize
ld hl,msg_op ;opening message display
call msgout
prompt: ld a,">" ;main routine
call putchar ;prompt display
call getchar
call putchar
cp "?" ;help ?
call z,help
cp "d" ;memory display?
call z,dump
cp "m" ;memory rewrite ?
call z,memory
cp "l" ;hex file load?
call z,loadhex
cp "j" ;address jump?
call z,jump
cp "i" ;i/o register rewite
call z,ioreg
cp "c"
call z,calling ;address call
cp 0x0d
jr z,prompt
cp 0x00
jr z,prompt
call cr
jr prompt
help: ld hl,help_msg ;help ?
call msgout
ret
cr:
ld a,0x0d
call putchar
ret
jump: ;address jump?
ld a," "
call putchar
call input_hl ;dump address input
cp 0x00
jr nz,crret
ld a," "
call putchar
ld a,"y"
call putchar
ld a,":"
call putchar
call getchar
cp "y"
jr nz,crret
call cr
jp (HL)
crret:
call cr
ret
calling: ;address call?
ld a," "
call putchar
call input_hl ;call address input
cp 0x00
jr nz,crret
ld a," "
call putchar
ld a,"y"
call putchar
ld a,":"
call putchar
call getchar
cp "y"
jr nz,crret
call cr
ld de,callret
push de
jp (HL)
callret:
ret
loadhex:
call loadhexline ;load 1line Hex file
cp 0xff ;hex file read err
jr z,loadhexerr
cp 0x01 ;hex file end?
jr nz,loadhex
ld a,0x0d
call putchar
ld a,"O"
call putchar
ld a,"K"
call putchar
ld a,0x0d
call putchar
ret
loadhexerr:
ld a,0x0d ;hex file read skip
call putchar
ld a,"E"
call putchar
ld a,"R"
call putchar
ld a,"R"
call putchar
ld a,0x0d
call putchar
ret
loadhexline:
ld a,0x0d
call putchar
ld d,0x00 ;checksum count clr
call getchar ;record mark is ":"
cp ":"
jr nz,loadhexlineerr
call input_l ;data size 1byte
ld b,l ;checksum = checksum + data size
ld a,d
add b
ld d,a
call input_hl ;offset address 2byte
push hl
pop ix ;offset address HLreg >> IXreg
ld a,d ;checksum = checksum + address Low
add l
add h ;checksum = checksum + address Hi
ld d,a
call input_l ;record type
ld a,l
cp 0x00 ;data record
jr nz,checkrecord
;; *** data record job ****
data_hex:
call input_l ;read hex 1byte in Lreg(hex)
ld (ix),l ;offset address < hex data
inc ix ;offset address +1
ld a,l
add d ;cheksum Dreg = Dreg + Lreg
ld d,a
djnz data_hex ;Breg(data size) == 0?
call input_l ;chechsum OK?
ld a,d
add l
cp 0x00
jr nz,loadhexlineerr
call getchar
cp 0x0a ;load 1line hex LF?
jr nz,loadhexlineerr
ld a,0x00
ret
checkrecord: ;end record ?
cp 0x01
jr nz,loadhexlineerr
call input_l
ld a,l
cp 0xff
jr nz,loadhexlineerr
ld a,0x01
ret
loadhexlineerr:
ld a,0xff ;read record err (no support)
ret
dump: ;memory dump
ld a," "
call putchar
call input_hl ;dump address input
cp 0x00
jr z,dump1
push iy ;memory dump address set
pop hl
dump1:
call dump_hl ;memory dump
push hl ;memory address IY set
pop iy
ret
memory: ;memory change
ld a," " ;space
call putchar
call input_hl ;change memory address
cp 0x00
jr z,memory1 ;no address hex code
ld a,0x0d
call putchar
ret
memory1:
ld a," " ;current memory display
call putchar
ld a,(HL)
call hex_a_disp
ld a," "
call putchar
push hl
call input_l ;new memory conntents input
cp 0x00
jr z,memory2
pop hl
xor a
ret
memory2:
ld c,l ;memory contents update
pop hl
ld (hl),c
ld a,0x0d
call putchar
ret
ioreg: ;ioreg change
ld a," " ;space
call putchar
call input_l ;change i/o register
cp 0x00
jr z,ioreg1 ;no address hex code
ld a,0x0d
call putchar
ret
ioreg1:
ld a," " ;current i/o address display
call putchar
ld b,0x00
ld c,l
in a,(c)
call hex_a_disp
ld a," "
call putchar
call input_l ;new i/o conntents address input
cp 0x00
jr z,ioreg2
xor a
ret
ioreg2:
ld a,l ;new i/o address update
out (c),a
ld a,0x0d
call putchar
ret
input_l: ;input Lreg hex (1byte)
push bc
ld b,0x02
jr input_loop
input_hl: ;input HLreg hex (2byte)
push bc
ld b,0x04
input_loop:
ld hl,0x0000 ;HL reg cler
jr input_hl2
shift_hl:
add hl,hl ;HL reg shift left 4bit
add hl,hl
add hl,hl
add hl,hl
input_hl2:
call getchar ;input ascii hex 1char
call putchar
call ascii_hex ;ascii hex 1char >> Areg
cp 0xff
jr z,input_hl_err
and 0x0f ;Areg low order 4bit >> Lreg
or l
ld l,a
djnz shift_hl
input_hl_end:
pop bc
xor a ;OK >> Areg 0x00
ret
input_hl_err:
ld a,0xff ;NG >> Areg 0xff
pop bc
ret
dump_hl: ;memory dump 1line(+0 -- +f)
ld a,0x0d
call putchar
push hl
ld hl,dump_msg ;dump address msg output
call msgout
pop hl
ld a,h ;dump address HLreg
call hex_a_disp ;dump address output
ld a,l
call hex_a_disp
ld a," "
call putchar
call putchar
ld b,0x10 ;address --> address +0f
hl_disp:
ld a,(HL) ;dump addres data (HL)
inc HL
call hex_a_disp
ld a," "
call putchar
djnz hl_disp
ld a,0x0d
call putchar
ret
hex_a_disp: ;Areg(HEX) >> putchar(areg)
push af
rrca ;7-4bit Right shift
rrca
rrca
rrca
call hex_ascii ;3-0bit Hex >> Hex ascii(0-F)
call putchar ;7-4bit putchar
pop af
call hex_ascii ;3-0bit Hex >> Hex ascii(0-F)
call putchar ;3-0bit putchar
ret
ascii_hex:
sub 0x30
jr c,err_hex
cp 0x0A ;0-9
jr c,hex_1_9
sub 0x11
cp 0x06 ;A-F
jr c,hex_A_F
sub 0x20
cp 0x06 ;a-f
jr nc,err_hex
hex_A_F:
add 0x0a
hex_1_9:
ret
err_hex:ld a,0xff
ret
hex_ascii: ;Areg(HEX) >> Areg(ascii code)
and a,0x0f
cp 0x0a
jr c,ascii0_9
add 0x37
ret
ascii0_9:
add 0x30
ret
msgout:
ld a,(hl) ;(HL)reg is output disp at 0x00
cp 0x00
ret z
call putchar
inc hl
jr msgout
getchar:
in a,(USARTC)
bit 1,a
jr z,getchar
in a,(USARTD)
ret
putchar:push af
putchar01:
in a,(USARTC)
bit 0,a
jr z,putchar01
pop af
out (USARTD),a
ret
;
com_init:
xor a
ld b,3
usartinit01:
out (USARTC),a ;dummy command
djnz usartinit01
ld a,0b01000000 ;reset commmand
out (USARTC),a
ld a,0b01001110 ;1 stop bit,Parity disble,8char,1/16
out (USARTC),a
ld a,0b00110111 ;RxEnable,TxEnable,RTS=0,DTR=0
out (USARTC),a
ret
;
msg_op: .str "Monitor Z80+8251+8255 (0xa000) ver0.71 by Pinecone 2020/09/03"
.db 0x0d
.db 0x00
help_msg:
.db 0x0d
.str "? Help"
.db 0x0d
.str "d MemoryDump"
.db 0x0d
.str "m MemoryChange"
.db 0x0d
.str "l HexFileLoad"
.db 0x0d
.str "j jump"
.db 0x0d
.str "i I/oRegister"
.db 0x0d
.str "c Call"
.db 0x0d
.db 0x00
dump_msg:
.str "addr +0 +1 +2 +3 +4 +5 +6 +7 +8 +9 +A +B +C +D +E +F"
.db 0x0d
.db 0x00
.end同じく、HEXファイルです。
:03A00000C300A1F9
:20A10000217DA3CD4BA33E3ECD5EA3CD55A3CD5EA3FE3FCC41A1FE64CC36A2FE6DCC4CA250
:20A12000FE6CCCA3A1FE6ACC4EA1FE69CC80A2FE63CC78A1FE0D28CEFE0028CACD48A11828
:20A14000C521BDA3CD4BA3C93E0DCD5EA3C93E20CD5EA3CDBBA2FE00201A3E20CD5EA33E5B
:20A1600079CD5EA33E3ACD5EA3CD55A3FE792004CD48A1E9CD48A1C93E20CD5EA3CDBBA27E
:20A18000FE0020F03E20CD5EA33E79CD5EA33E3ACD5EA3CD55A3FE7920DACD48A111A2A17A
:20A1A000D5E9C9CDDDA1FEFF2819FE0120F53E0DCD5EA33E4FCD5EA33E4BCD5EA33E0DCD98
:20A1C0005EA3C93E0DCD5EA33E45CD5EA33E52CD5EA33E52CD5EA33E0DCD5EA3C93E0DCD95
:20A1E0005EA31600CD55A3FE3A2048CDB6A2457A8057CDBBA2E5DDE17A858457CDB6A27DDF
:20A20000FE002020CDB6A2DD7500DD237D825710F3CDB6A27A85FE002019CD55A3FE0A20E8
:20A22000123E00C9FE01200BCDB6A27DFEFF20033E01C93EFFC93E20CD5EA3CDBBA2FE00B7
:20A240002803FDE5E1CDE1A2E5FDE1C93E20CD5EA3CDBBA2FE0028063E0DCD5EA3C93E2072
:20A26000CD5EA37ECD12A33E20CD5EA3E5CDB6A2FE002803E1AFC94DE1713E0DCD5EA3C9D7
:20A280003E20CD5EA3CDB6A2FE0028063E0DCD5EA3C93E20CD5EA306004DED78CD12A33EBB
:20A2A00020CD5EA3CDB6A2FE002802AFC97DED793E0DCD5EA3C9C506021803C5060421004E
:20A2C00000180429292929CD55A3CD5EA3CD25A3FEFF2809E60FB56F10E9C1AFC93EFFC11F
:20A2E000C93E0DCD5EA3E5210CA4CD4BA3E17CCD12A37DCD12A33E20CD5EA3CD5EA306101D
:20A300007E23CD12A33E20CD5EA310F43E0DCD5EA3C9F50F0F0F0FCD3FA3CD5EA3F1CD3F5D
:20A32000A3CD5EA3C9D6303813FE0A380ED611FE063806D620FE063003C60AC93EFFC9E669
:20A340000FFE0A3803C637C9C630C97EFE00C8CD5EA32318F6DB85CB4F28FADB84C9F5DB4F
:20A3600085CB4728FAF1D384C9AF0603D38510FC3E40D3853E4ED3853E37D385C94D6F6E7D
:20A3800069746F72205A38302B383235312B3832353520283078613030302920766572307C
:20A3A0002E3731202062792050696E65636F6E6520323032302F30392F30330D000D3F2014
:20A3C00048656C700D64204D656D6F727944756D700D6D204D656D6F72794368616E6765FB
:20A3E0000D6C2048657846696C654C6F61640D6A206A756D700D6920492F6F5265676973D5
:20A400007465720D632043616C6C0D006164647220202B30202B31202B32202B33202B34AC
:20A42000202B35202B36202B37202B38202B39202B41202B42202B43202B44202B45202B81
:03A44000460D00C6
:00000001FF
