Z80(Z80+8251+8255)と同様にZ80(Z80+SIO+PIO)についてもRAM64K化について確認を行っていきたいと思います。
まずは「最初のモニタ」上で動作する0xa000から始まるモニタを作成します。
開始アドレスの変更と、スタックポインタ、SIOの初期化をコメントアウトして無効にします。
.org 0xa000
jp start
.org 0xa100
start: ;cold start
; ld sp,0x0000 ;stack pointer set
; call sio_init ;serial channel initialize
; call pio_init ;Parallel port initialize
ld hl,msg_op ;opening message display
call msgout「最初のモニタ」でｌコマンド（HEX ｆｉｌｅ LOAD）で0xa000から始まるモニタを読み込みます。
jコマンドで 0xa000にジャンプして、モニタを起動します。
iコマンドで、i/oアドレスの0x80の内容を 0x03に変更します。（ROMからRAMへ切り替わり、切り替え表示のLEDがRAM側に点灯します。）
mコマンドで0x0000の内容を任意の値に変更できるか確認します。
Monitor Z80+SIO+PIO ver0.71 by Pinecone 2020/09/02
>l
03A00000C300A1F9
20A1000021B9A3CD4BA33E3ECD5EA3CD55A3CD5EA3FE3FCC41A1FE64CC36A2FE6DCC4CA214
・
中略
・
1DA46000202B37202B38202B39202B41202B42202B43202B44202B45202B460D00F2
00000001FF
OK
>
>j a000 y:
Monitor Z80+SIO+PIO (0xa000) ver0.71 by Pinecone 2020/09/08
>i 80 78 03
>m 0000 00 ff
>m 0000 FF
>ちゃんと 0x0000の内容を変更できたみたいです。
次回は、RAM６４Kに切り替えるｔコマンドと、SDCARDのブロック読み書きのコマンドを追加したいと思います。
以下 0xa000から起動できるモニタソースです。
; Z80+SIO+PIO monitor ver0.71 by Pinecone 2020/09/08
;
; Z80 cpu
; rom 0000h -- 7fffh
; ram 8000h -- ffffh
; External clock 4.9142MHz
; SIO serial communication A-CH
; extemal Clock 0.6144MHz (4.9152MHz TC74HC4040 1/8 Frequency division)
; Band Rate:38400 8bits 1Stopbits none Parity (81N)
; assembler
; program start A000H
; main A100H
;
; assemblers ASxxxx and ASlink V5.10
; file name Z80_SIO_PIO_moni_a000.asm
; $ asz80 -l -s -o Z80_SIO_PIO_moni_a000.asm
; $ aslink -i Z80_SIO_PIO_moni.a000
; z80_SIO_PIO_moni :L command hex load j command 0a000
;
.z80
.area TEST(ABS)
;; Z80 PIO
PIOAD .equ 0x88 ;PIO-A PORT DATA REG
PIOAC .equ 0x89 ;PIO-A PORT CONTL REG
PIOBD .equ 0x8a ;PIO-B PORT DATA REG
PIOBC .equ 0x8b ;PIO-B PORT CONTL REG
;; Z80 SIO
SIOAD .equ 0x84 ;SIO A-CH DATA REG
SIOAC .equ 0x85 ;SIO A-CH CONTL REG
SIOBD .equ 0x86 ;SIO B-CH DATA REG
SIOBC .equ 0x87 ;SIO B-CH CONTL REG
.org 0xa000
jp start
.org 0xa100
start: ;cold start
; ld sp,0x0000 ;stack pointer set
; call sio_init ;serial channel initialize
; call pio_init ;Parallel port initialize
ld hl,msg_op ;opening message display
call msgout
prompt: ld a,">" ;main routine
call putchar ;prompt display
call getchar
call putchar
cp "?" ;help ?
call z,help
cp "d" ;memory display?
call z,dump
cp "m" ;memory rewrite ?
call z,memory
cp "l" ;hex file load?
call z,loadhex
cp "j" ;address jump?
call z,jump
cp "i" ;i/o register rewite
call z,ioreg
cp "c"
call z,calling ;address call
cp 0x0d
jr z,prompt
cp 0x00
jr z,prompt
call cr
jr prompt
help: ld hl,help_msg ;help ?
call msgout
ret
cr:
ld a,0x0d
call putchar
ret
jump: ;address jump?
ld a," "
call putchar
call input_hl ;dump address input
cp 0x00
jr nz,crret
ld a," "
call putchar
ld a,"y"
call putchar
ld a,":"
call putchar
call getchar
cp "y"
jr nz,crret
call cr
jp (HL)
crret:
call cr
ret
calling: ;address call?
ld a," "
call putchar
call input_hl ;call address input
cp 0x00
jr nz,crret
ld a," "
call putchar
ld a,"y"
call putchar
ld a,":"
call putchar
call getchar
cp "y"
jr nz,crret
call cr
ld de,callret
push de
jp (HL)
callret:
ret
loadhex:
call loadhexline ;load 1line Hex file
cp 0xff ;hex file read err
jr z,loadhexerr
cp 0x01 ;hex file end?
jr nz,loadhex
ld a,0x0d
call putchar
ld a,"O"
call putchar
ld a,"K"
call putchar
ld a,0x0d
call putchar
ret
loadhexerr:
ld a,0x0d ;hex file read skip
call putchar
ld a,"E"
call putchar
ld a,"R"
call putchar
ld a,"R"
call putchar
ld a,0x0d
call putchar
ret
loadhexline:
ld a,0x0d
call putchar
ld d,0x00 ;checksum count clr
call getchar ;record mark is ":"
cp ":"
jr nz,loadhexlineerr
call input_l ;data size 1byte
ld b,l ;checksum = checksum + data size
ld a,d
add b
ld d,a
call input_hl ;offset address 2byte
push hl
pop ix ;offset address HLreg >> IXreg
ld a,d ;checksum = checksum + address Low
add l
add h ;checksum = checksum + address Hi
ld d,a
call input_l ;record type
ld a,l
cp 0x00 ;data record
jr nz,checkrecord
;; *** data record job ****
data_hex:
call input_l ;read hex 1byte in Lreg(hex)
ld (ix),l ;offset address < hex data
inc ix ;offset address +1
ld a,l
add d ;cheksum Dreg = Dreg + Lreg
ld d,a
djnz data_hex ;Breg(data size) == 0?
call input_l ;chechsum OK?
ld a,d
add l
cp 0x00
jr nz,loadhexlineerr
call getchar
cp 0x0a ;load 1line hex LF?
jr nz,loadhexlineerr
ld a,0x00
ret
checkrecord: ;end record ?
cp 0x01
jr nz,loadhexlineerr
call input_l
ld a,l
cp 0xff
jr nz,loadhexlineerr
ld a,0x01
ret
loadhexlineerr:
ld a,0xff ;read record err (no support)
ret
dump: ;memory dump
ld a," "
call putchar
call input_hl ;dump address input
cp 0x00
jr z,dump1
push iy ;memory dump address set
pop hl
dump1:
call dump_hl ;memory dump
push hl ;memory address IY set
pop iy
ret
memory: ;memory change
ld a," " ;space
call putchar
call input_hl ;change memory address
cp 0x00
jr z,memory1 ;no address hex code
ld a,0x0d
call putchar
ret
memory1:
ld a," " ;current memory display
call putchar
ld a,(HL)
call hex_a_disp
ld a," "
call putchar
push hl
call input_l ;new memory conntents input
cp 0x00
jr z,memory2
pop hl
xor a
ret
memory2:
ld c,l ;memory contents update
pop hl
ld (hl),c
ld a,0x0d
call putchar
ret
ioreg: ;ioreg change
ld a," " ;space
call putchar
call input_l ;change i/o register
cp 0x00
jr z,ioreg1 ;no address hex code
ld a,0x0d
call putchar
ret
ioreg1:
ld a," " ;current i/o address display
call putchar
ld b,0x00
ld c,l
in a,(c)
call hex_a_disp
ld a," "
call putchar
call input_l ;new i/o conntents address input
cp 0x00
jr z,ioreg2
xor a
ret
ioreg2:
ld a,l ;new i/o address update
out (c),a
ld a,0x0d
call putchar
ret
input_l: ;input Lreg hex (1byte)
push bc
ld b,0x02
jr input_loop
input_hl: ;input HLreg hex (2byte)
push bc
ld b,0x04
input_loop:
ld hl,0x0000 ;HL reg cler
jr input_hl2
shift_hl:
add hl,hl ;HL reg shift left 4bit
add hl,hl
add hl,hl
add hl,hl
input_hl2:
call getchar ;input ascii hex 1char
call putchar
call ascii_hex ;ascii hex 1char >> Areg
cp 0xff
jr z,input_hl_err
and 0x0f ;Areg low order 4bit >> Lreg
or l
ld l,a
djnz shift_hl
input_hl_end:
pop bc
xor a ;OK >> Areg 0x00
ret
input_hl_err:
ld a,0xff ;NG >> Areg 0xff
pop bc
ret
dump_hl: ;memory dump 1line(+0 -- +f)
ld a,0x0d
call putchar
push hl
ld hl,dump_msg ;dump address msg output
call msgout
pop hl
ld a,h ;dump address HLreg
call hex_a_disp ;dump address output
ld a,l
call hex_a_disp
ld a," "
call putchar
call putchar
ld b,0x10 ;address --> address +0f
hl_disp:
ld a,(HL) ;dump addres data (HL)
inc HL
call hex_a_disp
ld a," "
call putchar
djnz hl_disp
ld a,0x0d
call putchar
ret
hex_a_disp: ;Areg(HEX) >> putchar(areg)
push af
rrca ;7-4bit Right shift
rrca
rrca
rrca
call hex_ascii ;3-0bit Hex >> Hex ascii(0-F)
call putchar ;7-4bit putchar
pop af
call hex_ascii ;3-0bit Hex >> Hex ascii(0-F)
call putchar ;3-0bit putchar
ret
ascii_hex:
sub 0x30
jr c,err_hex
cp 0x0A ;0-9
jr c,hex_1_9
sub 0x11
cp 0x06 ;A-F
jr c,hex_A_F
sub 0x20
cp 0x06 ;a-f
jr nc,err_hex
hex_A_F:
add 0x0a
hex_1_9:
ret
err_hex:ld a,0xff
ret
hex_ascii: ;Areg(HEX) >> Areg(ascii code)
and a,0x0f
cp 0x0a
jr c,ascii0_9
add 0x37
ret
ascii0_9:
add 0x30
ret
msgout:
ld a,(hl) ;(HL)reg is output disp at 0x00
cp 0x00
ret z
call putchar
inc hl
jr msgout
getchar:
in a,(SIOAC)
bit 0,a
jr z,getchar
in a,(SIOAD)
ret
putchar:push af
putchar01:
in a,(SIOAC)
bit 2,a
jr z,putchar01
pop af
out (SIOAD),a
ret
;
sio_init:
ld b,0x0b
ld c,SIOBC
ld hl,SIO_INIT_TB_B
otir
ld b,0x09
ld c,SIOAC
ld hl,SIO_INIT_TB_A
otir
ret
pio_init:
;; PIO-A PORT INIT
ld a,0x00 ;int bector set
out (PIOAC),a
ld a,0b11001111 ;mode 3 set(bit control)
out (PIOAC),a
ld a,0b00001111 ;portA 7-4 output 3-0 input
out (PIOAC),a
ld a,0b00000111 ;int disple
out (PIOAC),a
ld a,0b11111111 ;mask bit
out (PIOAC),a
;; PIO-B PORT INIT
ld a,0x00 ;int bector set
out (PIOBC),a
ld a,0b11001111 ;mode 3 set(bit control)
out (PIOBC),a
ld a,0b11111111 ;portB 7-0 input
out (PIOBC),a
ld a,0b00000111 ;int disple
out (PIOBC),a
ld a,0b11111111 ;mask bit
out (PIOBC),a
ret
;
SIO_INIT_TB_A:
.db 0x18 ;ch RESET
.db 0x14 ;WR4 set ,int reset
.db 0b01000100 ;x16 8bitchar 1stopbit nonparity
.db 0x03 ;WR3 set
.db 0b11000001 ;rx 8bit char ,RxEnable
.db 0x05 ;WR5 set
.db 0b01101000 ;tx 8bit char ,TxEnable ,DTR=0 ,RTS=0
.db 0x11 ;WR1 set ,int reset
.db 0b00000000 ;non int
SIO_INIT_TB_B:
.db 0x18 ;ch RESET
.db 0x02 ;WR2 set
.db 0x00 ;int tabel 0x00
.db 0x14 ;WR4 set ,int reset
.db 0b01000100 ;x16 8bitchar 1stopbit nonparity
.db 0x03 ;WR3 set
.db 0b11000001 ;rx 8bit char ,RxEnable
.db 0x05 ;WR5 set
.db 0b01101000 ;tx 8bit char ,TxEnable ,DTR=0 ,RTS=0
.db 0x11 ;WR1 set ,int reset
.db 0b00000000 ;non int
;
msg_op: .str "Monitor Z80+SIO+PIO (0xa000) ver0.71 by Pinecone 2020/09/08"
.db 0x0d
.db 0x00
help_msg:
.db 0x0d
.str "? Help"
.db 0x0d
.str "d MemoryDump"
.db 0x0d
.str "m MemoryChange"
.db 0x0d
.str "l HexFileLoad"
.db 0x0d
.str "j jump"
.db 0x0d
.str "i I/oRegister"
.db 0x0d
.str "c Call"
.db 0x0d
.db 0x00
dump_msg:
.str "addr +0 +1 +2 +3 +4 +5 +6 +7 +8 +9 +A +B +C +D +E +F"
.db 0x0d
.db 0x00
.end同じく、HEXファイルです。
:03A00000C300A1F9
:20A1000021B9A3CD4BA33E3ECD5EA3CD55A3CD5EA3FE3FCC41A1FE64CC36A2FE6DCC4CA214
:20A12000FE6CCCA3A1FE6ACC4EA1FE69CC80A2FE63CC78A1FE0D28CEFE0028CACD48A11828
:20A14000C521F7A3CD4BA3C93E0DCD5EA3C93E20CD5EA3CDBBA2FE00201A3E20CD5EA33E21
:20A1600079CD5EA33E3ACD5EA3CD55A3FE792004CD48A1E9CD48A1C93E20CD5EA3CDBBA27E
:20A18000FE0020F03E20CD5EA33E79CD5EA33E3ACD5EA3CD55A3FE7920DACD48A111A2A17A
:20A1A000D5E9C9CDDDA1FEFF2819FE0120F53E0DCD5EA33E4FCD5EA33E4BCD5EA33E0DCD98
:20A1C0005EA3C93E0DCD5EA33E45CD5EA33E52CD5EA33E52CD5EA33E0DCD5EA3C93E0DCD95
:20A1E0005EA31600CD55A3FE3A2048CDB6A2457A8057CDBBA2E5DDE17A858457CDB6A27DDF
:20A20000FE002020CDB6A2DD7500DD237D825710F3CDB6A27A85FE002019CD55A3FE0A20E8
:20A22000123E00C9FE01200BCDB6A27DFEFF20033E01C93EFFC93E20CD5EA3CDBBA2FE00B7
:20A240002803FDE5E1CDE1A2E5FDE1C93E20CD5EA3CDBBA2FE0028063E0DCD5EA3C93E2072
:20A26000CD5EA37ECD12A33E20CD5EA3E5CDB6A2FE002803E1AFC94DE1713E0DCD5EA3C9D7
:20A280003E20CD5EA3CDB6A2FE0028063E0DCD5EA3C93E20CD5EA306004DED78CD12A33EBB
:20A2A00020CD5EA3CDB6A2FE002802AFC97DED793E0DCD5EA3C9C506021803C5060421004E
:20A2C00000180429292929CD55A3CD5EA3CD25A3FEFF2809E60FB56F10E9C1AFC93EFFC11F
:20A2E000C93E0DCD5EA3E52146A4CD4BA3E17CCD12A37DCD12A33E20CD5EA3CD5EA30610E3
:20A300007E23CD12A33E20CD5EA310F43E0DCD5EA3C9F50F0F0F0FCD3FA3CD5EA3F1CD3F5D
:20A32000A3CD5EA3C9D6303813FE0A380ED611FE063806D620FE063003C60AC93EFFC9E669
:20A340000FFE0A3803C637C9C630C97EFE00C8CD5EA32318F6DB85CB4728FADB84C9F5DB57
:20A3600085CB5728FAF1D384C9060B0E8721AEA3EDB306090E8521A5A3EDB3C93E00D3893D
:20A380003ECFD3893E0FD3893E07D3893EFFD3893E00D38B3ECFD38B3EFFD38B3E07D38B2C
:20A3A0003EFFD38BC918144403C105681100180200144403C1056811004D6F6E69746F72EB
:20A3C000205A38302B53494F2B50494F20283078613030302920766572302E373120206293
:20A3E000792050696E65636F6E6520323032302F30392F30380D000D3F2048656C700D640D
:20A40000204D656D6F727944756D700D6D204D656D6F72794368616E67650D6C20486578F6
:20A4200046696C654C6F61640D6A206A756D700D6920492F6F52656769737465720D632077
:20A4400043616C6C0D006164647220202B30202B31202B32202B33202B34202B35202B3646
:1DA46000202B37202B38202B39202B41202B42202B43202B44202B45202B460D00F2
:00000001FF
