前回で64KRAMへの切り替えができましたので、今回はモニタにｔコマンドを追加して、ROMのモニタをRAMにコピーし、RAMのモニタを起動するようにしたいと思います。
過去の記事でZ8S180でtコマンドを作成しているので、これを基に切り替えのi/o操作の部分を変更して作成します。
ステップ１：ROMのモニタを上位RAM(0x8000～0xffff）に一時的にコピーする。(コピー先先頭アドレス0x8000）。
tコマンドの該当部分のプログラムは次のようになります。
temp_addr .equ 0x8000 ;moni move temprary address
trance:
call call_yes_msg
call getchar
cp "y"
jr nz,crret_t
call cr
;ram 0x8000 to 0xffff
ld hl,0x0000 ;moni copy at temp_addr
ld de,temp_addr
ld bc,prog_end
ldir
ld hl,move_prog+temp_addr
jp (hl) ;temprary address jump
;ステップ２：0x8000にコピーしたｔコマンドのプログラムに実行を移し、ROMをRAMに切り替え、0x8000からのモニタをRAM上の0x0000から始まるアドレスにコピーする。コピーが完了したら、RAM上のモニタのtコマンドのプログラムに制御を移す。
該当のプログラムは次のようになります。
ROM_RAM_SW_PORT .equ 0x84 ;D-FF rom/ram sw port
ON_RAM .equ 0x03 ;D0 0:ROM 1:RAM
ON_ROM .equ 0x00 ;D1 0:LED_ROM 1:RAM_LED
move_prog:
ld a,ON_RAM ;ram 0x0000 to 0x7fff setting
out (ROM_RAM_SW_PORT),a
ld hl,temp_addr ;moni moveing at ram 0x0000 to prog_end
ld de,0x0000
ld bc,prog_end
ldir
ld hl,go_moni
jp (hl) ;ram monitor jumpステップ３：コピー完了のメッセージを出して、モニタをスタートする。
go_moni:
call cr
ld hl,ram_msg
call msgout
jp start
ram_msg:
.str "RAM area switching monitor"
.db 0x0d
.db 0x00実際にモニタを実行してみました。
ROMのモニタ上でtコマンドを実行して、RAM上でのモニタに制御を移し、RAM領域の0x0003を書き換えしてみました。
>Monitor TMPZ84C015 CPU ver0.72(SPI) by Pinecone 2019/9/6
>t Yes:
RAM area switching monitor
Monitor TMPZ84C015 CPU ver0.72(SPI) by Pinecone 2019/9/6
>d 0000
addr +0 +1 +2 +3 +4 +5 +6 +7 +8 +9 +A +B +C +D +E +F
0000 C3 00 01 FF FF FF FF FF FF FF FF FF FF FF FF FF
>m 0003 FF 77
>d 0000
addr +0 +1 +2 +3 +4 +5 +6 +7 +8 +9 +A +B +C +D +E +F
0000 C3 00 01 77 FF FF FF FF FF FF FF FF FF FF FF FF
>m 0003 77
>全体のモニタソースプログラムは下記の通りです。（ちょっと長いです）
; TMPZ84C015 monitor ver0.72(SPI) by Pinecone 2019/9/6
;
; TMPZ84C015 cpu
; rom 0000h -- 7fffh
; ram 8000h -- ffffh
; External clock 20MHz
; TMPZ84C015 serial communication (CH-B)
; extemal Clock 0.1536MHz (1/16=9600bps)
; assembler
; program start 0000H
; main 0100H
;
; assemblers ASxxxx and ASlink V5.10
; file name tmpz84c015_moni071.asm
; $ asz80 -l -s -o tmpz84c015_moni071.asm
; $ aslink -i tmpz84c015_moni071
; $ rom-writer TL866-2 plus tmpz84c015_moni071.ihx
;
.z80
SIOBD .equ 0x1A ;SIO-B CH DATA REG
SIOBC .equ 0x1B ;SIO-B CH CONTL REG
PIOAD .equ 0x1c ;PIO-A CH DATA REG
PIOAC .equ 0x1d ;PIO-A CH CONTL REG
;OUTPUT-PORT
S_DI .equ 7 ;0b10000000 D7
S_CS .equ 6 ;0b01000000 D6
S_CLK .equ 5 ;0b00100000 D5
;INPUT-PORT
DO .equ 0 ;0b00000001 D0
temp_addr .equ 0x8000 ;moni move temprary address
ROM_RAM_SW_PORT .equ 0x84 ;D-FF rom/ram sw port
ON_RAM .equ 0x03 ;D0 0:ROM 1:RAM
ON_ROM .equ 0x00 ;D1 0:LED_ROM 1:RAM_LED
.area TEST(ABS)
.org 0x0000
jp start
.org 0x100
start: ;cold start
ld sp,0x0000 ;stack pointer set
call com_init ;serial channel initialize
call pioainit ;Parallel port A initialize
ld hl,msg_op ;opening message display
call msgout
prompt: ld a,">" ;main routine
call putchar ;prompt display
call getchar
call putchar
cp "?" ;help ?
call z,help
cp "d" ;memory display?
call z,dump
cp "m" ;memory rewrite ?
call z,memory
cp "l" ;hex file load?
call z,loadhex
cp "j" ;address jump?
call z,jump
cp "i" ;i/o register rewite
call z,ioreg
cp "c"
call z,calling ;address call
cp "t"
call z,trance ;moni 64Kmemory trance
cp "a"
call z,spi_card ;read/write spi sd-card
cp 0x0d
jr z,prompt
cp 0x00
jr z,prompt
call cr
jr prompt
help: ld hl,help_msg ;help ?
call msgout
ret
cr:
ld a,0x0d
call putchar
ret
crret_t:
call cr
ret
trance:
call call_yes_msg
call getchar
cp "y"
jr nz,crret_t
call cr
;ram 0x8000 to 0xffff
ld hl,0x0000 ;moni copy at temp_addr
ld de,temp_addr
ld bc,prog_end
ldir
ld hl,move_prog+temp_addr
jp (hl) ;temprary address jump
;
move_prog:
ld a,ON_RAM ;ram 0x0000 to 0x7fff setting
out (ROM_RAM_SW_PORT),a
ld hl,temp_addr ;moni moveing at ram 0x0000 to prog_end
ld de,0x0000
ld bc,prog_end
ldir
ld hl,go_moni
jp (hl) ;ram monitor jump
;
go_moni:
call cr
ld hl,ram_msg
call msgout
jp start
jump: ;address jump?
ld a," "
call putchar
call input_hl ;dump address input
cp 0x00
jr nz,crret
ld a," "
call putchar
ld a,"y"
call putchar
ld a,":"
call putchar
call getchar
cp "y"
jr nz,crret
call cr
jp (HL)
crret:
call cr
ret
calling: ;address call?
ld a," "
call putchar
call input_hl ;call address input
cp 0x00
jr nz,crret
ld a," "
call putchar
ld a,"y"
call putchar
ld a,":"
call putchar
call getchar
cp "y"
jr nz,crret
call cr
ld de,callret
push de
jp (HL)
callret:
ret
loadhex:
call loadhexline ;load 1line Hex file
cp 0xff ;hex file read err
jr z,loadhexerr
cp 0x01 ;hex file end?
jr nz,loadhex
ld a,0x0d
call putchar
ld a,"O"
call putchar
ld a,"K"
call putchar
ld a,0x0d
call putchar
ret
loadhexerr:
ld a,0x0d ;hex file read skip
call putchar
ld a,"E"
call putchar
ld a,"R"
call putchar
ld a,"R"
call putchar
ld a,0x0d
call putchar
ret
loadhexline:
ld a,0x0d
call putchar
ld d,0x00 ;checksum count clr
call getchar ;record mark is ":"
cp ":"
jr nz,loadhexlineerr
call input_l ;data size 1byte
ld b,l ;checksum = checksum + data size
ld a,d
add b
ld d,a
call input_hl ;offset address 2byte
push hl
pop ix ;offset address HLreg >> IXreg
ld a,d ;checksum = checksum + address Low
add l
add h ;checksum = checksum + address Hi
ld d,a
call input_l ;record type
ld a,l
cp 0x00 ;data record
jr nz,checkrecord
;; *** data record job ****
data_hex:
call input_l ;read hex 1byte in Lreg(hex)
ld (ix),l ;offset address < hex data
inc ix ;offset address +1
ld a,l
add d ;cheksum Dreg = Dreg + Lreg
ld d,a
djnz data_hex ;Breg(data size) == 0?
call input_l ;chechsum OK?
ld a,d
add l
cp 0x00
jr nz,loadhexlineerr
call getchar
cp 0x0a ;load 1line hex LF?
jr nz,loadhexlineerr
ld a,0x00
ret
checkrecord: ;end record ?
cp 0x01
jr nz,loadhexlineerr
call input_l
ld a,l
cp 0xff
jr nz,loadhexlineerr
ld a,0x01
ret
loadhexlineerr:
ld a,0xff ;read record err (no support)
ret
dump: ;memory dump
ld a," "
call putchar
call input_hl ;dump address input
cp 0x00
jr z,dump1
push iy ;memory dump address set
pop hl
dump1:
call dump_hl ;memory dump
push hl ;memory address IY set
pop iy
ret
memory: ;memory change
ld a," " ;space
call putchar
call input_hl ;change memory address
cp 0x00
jr z,memory1 ;no address hex code
ld a,0x0d
call putchar
ret
memory1:
ld a," " ;current memory display
call putchar
ld a,(HL)
call hex_a_disp
ld a," "
call putchar
push hl
call input_l ;new memory conntents input
cp 0x00
jr z,memory2
pop hl
xor a
ret
memory2:
ld c,l ;memory contents update
pop hl
ld (hl),c
ld a,0x0d
call putchar
ret
ioreg: ;ioreg change
ld a," " ;space
call putchar
call input_l ;change i/o register
cp 0x00
jr z,ioreg1 ;no address hex code
ld a,0x0d
call putchar
ret
ioreg1:
ld a," " ;current i/o address display
call putchar
ld b,0x00
ld c,l
in a,(c)
call hex_a_disp
ld a," "
call putchar
call input_l ;new i/o conntents address input
cp 0x00
jr z,ioreg2
xor a
ret
ioreg2:
ld a,l ;new i/o address update
out (c),a
ld a,0x0d
call putchar
ret
call_yes_msg:
push hl
ld hl,yes_msg
call msgout
pop hl
ret
spi_card:
call getchar
cp "i"
call z,spi_init
cp "r"
call z,spi_read
cp "w"
call z,spi_write
ret
spi_read:
ld hl,read_block_no_msg
call msgout
call input_hl
cp 0x00
jr z,spi_read1
call cr
xor a
ret
spi_read1:
ld a,(r7)
bit 6,a
jp z,read_SD_ver2
ld a,h ;SDHC
ld (cmd17+03),a
ld a,l
ld (cmd17+04),a
jr spi_read2
read_SD_ver2:
ld a,h ;Ver2
ld (cmd17+02),a
ld a,l
ld (cmd17+03),a
spi_read2:
ld hl,save_addr_msg
call msgout
call input_hl
cp 0x00
jr z,cmd17_out
call cr
xor a
ret
cmd17_out:
call call_yes_msg
call getchar
cp "y"
jp nz,spi_ret
push hl
call dummy_data ;dummy data(0xff) out
ld hl,cmd17
call cmd_out ;cmd17 Issue
call r1_resp
cp 0x00 ;response is 0x00 read mode OK?
jr nz,cmd17_err
cmd17_st:
call r1_resp ;read data start response?
cp 0xfe ;data start byte 0xfe?
jr nz, cmd17_st
ld b,0x00 ;read data size 256byte
pop hl ;read data buff address
cmd17_r:
call resp ;read data
ld (hl),a
inc hl
djnz cmd17_r
ld b,0x00
cmd17_r2:
call resp
ld (hl),a ;read data
inc hl
djnz cmd17_r2
call resp ;crc Skipping read
call resp ;crc Skipping read
ld d,0xff ;dummy data 0xff(cs low)
call spi_8bit
;memory dump address
ld bc,0x0200
sbc hl,bc
;memory dump 512b
ld a,0x0d
call putchar
call hl_disp256 ;256bye dump
call putchar
call hl_disp256 ;256bye dump
call putchar
xor a
ret
cmd17_err:
pop hl
ld hl,cmd17_err_msg
call msgout
ret
hl_disp256:
push bc
ld b,0x00 ;dump data size 256bye
push hl
ld hl,dump_msg ;dump address msg output
call msgout
pop hl
ld a,h ;dump address HLreg
call hex_a_disp ;dump address output
ld a,l
call hex_a_disp
ld a," "
call putchar
call putchar
hl_disp256_loop:
ld a,(HL) ;dump addres data (HL)
inc HL
call hex_a_disp
ld a,b
cp 0x01 ;end dump size?
jr z,hl_disp256_loop1
ld a,b
and 0x0f
cp 0x01 ;0x?0-0x?f is 0x01(1line disp end?)
jr z,hl_disp256_cr
ld a," " ;space Insert
call putchar
jr hl_disp256_loop1
hl_disp256_cr:
ld a,0x0d
call putchar
ld a,h ;dump address HLreg
call hex_a_disp ;dump address output
ld a,l
call hex_a_disp
ld a," "
call putchar
call putchar
hl_disp256_loop1:
djnz hl_disp256_loop
ld a,0x0d
call putchar
pop bc
ret
spi_write:
ld hl,write_block_no_msg
call msgout
call input_hl
cp 0x00
jr z,spi_write1
call cr
xor a
ret
spi_write1:
ld a,(r7)
bit 6,a
jp z,write_SD_ver2
ld a,h ;SDHC
ld (cmd24+03),a
ld a,l
ld (cmd24+04),a
jr spi_write2
write_SD_ver2: ;Ver2
ld a,h
ld (cmd24+02),a
ld a,l
ld (cmd24+03),a
spi_write2:
ld hl,write_addr_msg
call msgout
call input_hl
cp 0x00
jr z,cmd24_out
call cr
xor a
ret
cmd24_out:
call call_yes_msg
call getchar
cp "y"
jp nz,spi_ret
push hl
call dummy_data
ld hl,cmd24
call cmd_out
call r1_resp
cp 0x00
jp nz,cmd24_err
ld d,0xfe
call spi_8bit
pop hl
ld b,0x00
cmd24_w:
ld d,(hl)
inc hl
call spi_8bit
djnz cmd24_w
ld b,0x00
cmd24_w2:
ld d,(hl)
inc hl
call spi_8bit
djnz cmd24_w2
ld d,0xff
call spi_8bit ;crc
call spi_8bit ;crc
call r1_resp
and 0x0f
cp 0x05
jr nz,cmd24_err2
cmd24_wch:
call r1_resp
cp 0x00
jr z,cmd24_wch
call dummy_data
ld bc,0x0200
sbc hl,bc
;memory dump 512b
ld a,0x0d
call putchar
call hl_disp256 ;256bye dump
call putchar
call hl_disp256 ;256bye dump
call putchar
xor a
ret
cmd24_err:
pop hl
cmd24_err2:
ld hl,cmd24_err_msg
call msgout
ret
spi_init:
call cmd17_24_copy
ld hl,spi_init_msg
call msgout
call call_yes_msg
call getchar
cp "y"
jp nz,spi_ret
call cr
call spi_card_init
ld hl,ok_msg
call msgout
ret
cmd17_24_copy:
ld b,0x06
ld hl,m_cmd17
ld de,cmd17
cmd17_copy:
ld a,(HL)
ld (DE),a
inc hl
inc de
djnz cmd17_copy
ld b,0x06
ld hl,m_cmd24
ld de,cmd24
cmd24_copy:
ld a,(HL)
ld (DE),a
inc hl
inc de
djnz cmd24_copy
ret
spi_card_init:
xor a
set S_CS,a ;CS="H"
set S_DI,a ;DI="H"
out (PIOAD),a
ld b,80 ;80 clok output
call loopspii
xor a
out (PIOAD),a ;CS="L" DI="L" CLK="L"
call cmd0_out
cp 0x01
jp nz,init_err
call cmd8_out
cp 0x01
jp nz,init_err
call cmd55_out
cp 0x01
jp nz,init_err
call acmd41_out
call cmd58_out
ld a,(r7)
bit 7,a
jp z,init_err
bit 6,a
jr z,SD_ver2
ld hl,sdhc_msg
init_msg:
call msgout
ret
SD_ver2:
ld hl,sd_ver2_msg
jr init_msg
cmd0_out:
ld hl,cmd0
call cmd_out
call r1_resp
push af
ld hl,cmd0_msg
call msgout
pop af
push af
call hex_a_disp
ld a,0x0d
call putchar
pop af
ret
cmd8_out:
call dummy_data
ld hl,cmd8
call cmd_out
call r1_resp
cp 0x01
ret nz
ld b,4
ld hl,r7
cmd8_r:
call resp
ld (hl),a
inc hl
djnz cmd8_r
cmd8_r_d:
ld hl,cmd8_msg
call msgout
ld a,0x01
call hex_a_disp
ld hl,r7
ld b,4
cmd8_r_d_loop:
ld a,(hl)
call hex_a_disp
inc hl
djnz cmd8_r_d_loop
ld a,0x0d
call putchar
ld a,0x01
ret
cmd55_out:
call dummy_data
ld hl,cmd55
call cmd_out
call r1_resp
push af
ld hl,cmd55_msg
call msgout
pop af
push af
call hex_a_disp
ld a,0x0d
call putchar
pop af
ret
acmd41_out:
call dummy_data
ld hl,acmd41 ;sd-card Initialize
call cmd_out
call r1_resp
cp 0x00
push af
ld hl,acmd41_msg
call msgout
pop af
push af
call hex_a_disp
ld a,0x0d
call putchar
pop af
ret z
call cmd55_out
jr acmd41_out
spi_ret:
call cr
ret
init_err:
ld hl,spi_init_err_msg
call msgout
call cr
jp start
cmd58_out:
call dummy_data
ld hl,cmd58
call cmd_out
call r1_resp
push af
ld b,4
ld hl,r7
cmd58_r:
call resp
ld (hl),a
inc hl
djnz cmd58_r
cmd58_r_d:
ld hl,cmd58_msg
call msgout
pop af
push af
call hex_a_disp
ld hl,r7
ld b,4
cmd58_r_d_loop:
ld a,(hl)
call hex_a_disp
inc hl
djnz cmd58_r_d_loop
ld a,0x0d
call putchar
pop af
ret
dummy_data:
xor a
set S_CS,a ;CS="H"
set S_DI,a ;DI="H"
out (PIOAD),a
ld b,8 ;1clok output
call loopspii
xor a
out (PIOAD),a
ret
loopspii:
res S_CLK,a ;CLK L
out (PIOAD),a
nop
nop
nop
nop
nop
nop
nop
nop
set S_CLK,a ;CLK H
out (PIOAD),a
nop
nop
nop
nop
nop
djnz loopspii
ret
r1_resp:
call resp
cp 0xff
jr z,r1_resp
ret
resp:
ld d,0xff
call spi_8bit
ld a,e
ret
cmd_out: ;command out
push hl
push bc
ld b,0x06 ;command line word count
cmd_out1:
ld d,(hl) ;command line area
call spi_8bit
inc hl
djnz cmd_out1
pop bc
pop hl
ret
spi_8bit: ;outdata Dreg,inputdata Ereg
push bc
ld c,0x00
ld b,0x08
loopspi:
xor a
rlc d
rra
res S_CLK,a ;CLK L
out (PIOAD),a
nop
nop
nop
nop
nop
nop
set S_CLK,a ;CLK H
out (PIOAD),a
in a,(PIOAD)
rrca
rl e
djnz loopspi
xor a
out (PIOAD),a
pop bc
ret
input_l: ;input Lreg hex (1byte)
push bc
ld b,0x02
jr input_loop
input_hl: ;input HLreg hex (2byte)
push bc
ld b,0x04
input_loop:
ld hl,0x0000 ;HL reg cler
jr input_hl2
shift_hl:
add hl,hl ;HL reg shift left 4bit
add hl,hl
add hl,hl
add hl,hl
input_hl2:
call getchar ;input ascii hex 1char
call putchar
call ascii_hex ;ascii hex 1char >> Areg
cp 0xff
jr z,input_hl_err
and 0x0f ;Areg low order 4bit >> Lreg
or l
ld l,a
djnz shift_hl
input_hl_end:
pop bc
xor a ;OK >> Areg 0x00
ret
input_hl_err:
ld a,0xff ;NG >> Areg 0xff
pop bc
ret
dump_hl: ;memory dump 1line(+0 -- +f)
ld a,0x0d
call putchar
push hl
ld hl,dump_msg ;dump address msg output
call msgout
pop hl
ld a,h ;dump address HLreg
call hex_a_disp ;dump address output
ld a,l
call hex_a_disp
ld a," "
call putchar
call putchar
ld b,0x10 ;address --> address +0f
hl_disp:
ld a,(HL) ;dump addres data (HL)
inc HL
call hex_a_disp
ld a," "
call putchar
djnz hl_disp
ld a,0x0d
call putchar
ret
hex_a_disp: ;Areg(HEX) >> putchar(areg)
push af
rrca ;7-4bit Right shift
rrca
rrca
rrca
call hex_ascii ;3-0bit Hex >> Hex ascii(0-F)
call putchar ;7-4bit putchar
pop af
call hex_ascii ;3-0bit Hex >> Hex ascii(0-F)
call putchar ;3-0bit putchar
ret
ascii_hex:
sub 0x30
jr c,err_hex
cp 0x0A ;0-9
jr c,hex_1_9
sub 0x11
cp 0x06 ;A-F
jr c,hex_A_F
sub 0x20
cp 0x06 ;a-f
jr nc,err_hex
hex_A_F:
add 0x0a
hex_1_9:
ret
err_hex:ld a,0xff
ret
hex_ascii: ;Areg(HEX) >> Areg(ascii code)
and a,0x0f
cp 0x0a
jr c,ascii0_9
add 0x37
ret
ascii0_9:
add 0x30
ret
msgout:
ld a,(hl) ;(HL)reg is output disp at 0x00
cp 0x00
ret z
call putchar
inc hl
jr msgout
getchar:in a,(SIOBC)
bit 0,a
jr z,getchar
in a,(SIOBD)
ret
putchar:push af
putchar01:
in a,(SIOBC)
bit 2,a
jr z,putchar01
pop af
out (SIOBD),a
ret
;
com_init:
ld b,12
ld hl,SIO_init_data
com_init01:
ld a,(HL)
out (SIOBC),a
inc hl
djnz com_init01
ret
pioainit:
ld b,3
ld hl,PIO_init_data
pioainit01:
ld a,(HL)
out (PIOAC),a
inc hl
djnz pioainit01
ret
PIO_init_data:
.db 0b11001111 ;PIOAC:set 0xcf: Mode3 (bit mode)
.db 0b00011111 ;PIOAC:set 0x1f: D4-D0=input D7-D5=output
.db 0b00000000 ;PIOAC:set 0x00: interrupt disables
;
SIO_init_data:
.db 0x00,0b00110000 ;WR0=WR0:set ,WR0: reset
.db 0x01,0b00000000 ;WR0=WR1:set ,WR1: all init reset
.db 0x02,0b00000000 ;WR0=WR2:set ,WR2: init set
.db 0x03,0b11000001 ;WR0=WR3:set ,WR3: RxBit=8bit Rx=ready
.db 0x04,0b01000100 ;WR0=WR4:set ,WR4: clock=1/16 stop=1bit parity=non
.db 0x05,0b11101010 ;WR0=WR5:set ,WR5: char=8bit DTR/RTS=EN Tx=ready
msg_op: .str "Monitor TMPZ84C015 CPU ver0.72(SPI) by Pinecone 2019/9/6"
.db 0x0d
.db 0x00
help_msg:
.db 0x0d
.str "? Help"
.db 0x0d
.str "d memory dump"
.db 0x0d
.str "m memory change address old new"
.db 0x0d
.str "l hex file load"
.db 0x0d
.str "j jump"
.db 0x0d
.str "i i/o register i/o-address old new"
.db 0x0d
.str "c call"
.db 0x0d
.str "t ram area trance monitor jump"
.db 0x0d
.str "ai spi(sd-card) Initialization"
.db 0x0d
.str "ar spi(sd-card) read (512byte/block) 0x0000-0xffff set"
.db 0x0d
.str "aw spi(sd-card) write (512byte/block) 0x0000-0xffff set"
.db 0x0d
.db 0x00
dump_msg:
.str "addr +0 +1 +2 +3 +4 +5 +6 +7 +8 +9 +A +B +C +D +E +F"
.db 0x0d
.db 0x00
cmd0_msg:
.str "CMD0:"
.db 0x00
cmd8_msg:
.str "CMD8:"
.db 0x00
cmd55_msg:
.str "CMD55:"
.db 0x00
acmd41_msg:
.str "ACMD41:"
.db 0x00
cmd58_msg:
.str "CMD58:"
.db 0x00
yes_msg:
.str " Yes:"
.db 0x00
ok_msg:
.str "OK"
.db 0x0d
.db 0x00
err_msg:
.str "ERR"
.db 0x0d
.db 0x00
read_block_no_msg:
.str " read block No:"
.db 0x00
write_block_no_msg:
.str " write block No:"
.db 0x00
save_addr_msg:
.str " save addr:"
.db 0x00
write_addr_msg:
.str " write addr:"
.db 0x00
spi_init_err_msg:
.str "Spi Init Err"
.db 0x0d
.db 0x00
cmd17_err_msg:
.str "cmd17 Err"
.db 0x0d
.db 0x00
cmd24_err_msg:
.str "cmd24 Err"
.db 0x0d
.db 0x00
sdhc_msg:
.str ":SDHC"
.db 0x0d
.db 0x00
sd_ver2_msg:
.str ":SD Ver2"
.db 0x0d
.db 0x00
spi_init_msg:
.str " spi(sd-card) Initialize :"
.db 0x00
ram_msg:
.str "RAM area switching monitor"
.db 0x0d
.db 0x00
cmd0: ;;48bit(6byte) Fixed length
.db 0x40 ;;command index
.db 0x00 ;;argument
.db 0x00 ;;argument
.db 0x00 ;;argument
.db 0x00 ;;argument
.db 0x95 ;;CRC
;cmd1:
; .db 0x41 ;;command init
; .db 0x00
; .db 0x00
; .db 0x00
; .db 0x00
; .db 0xf9 ;;CRC
cmd8:
.db 0x48
.db 0x00
.db 0x00
.db 0x01
.db 0xaa
.db 0x87
acmd41:
.db 0x69
.db 0x40
.db 0xff
.db 0x80
.db 0x00
.db 0xff
cmd58:
.db 0x7a
.db 0x00
.db 0x00
.db 0x00
.db 0x00
.db 0xff
cmd55:
.db 0x77
.db 0x00
.db 0x00
.db 0x00
.db 0x00
.db 0xff
cmd16:
.db 0x50
.db 0x00
.db 0x00
.db 0x02
.db 0x00
.db 0xff
m_cmd17:
.db 0x51
.db 0x00
.db 0x00
.db 0x02
.db 0x00
.db 0xff
m_cmd24:
.db 0x58
.db 0x00
.db 0x00
.db 0x02
.db 0x00
.db 0xff
prog_end:
.org 0xff00
cmd17:
.db 0x51
.db 0x00
.db 0x00
.db 0x02
.db 0x00
.db 0xff
cmd24:
.db 0x58
.db 0x00
.db 0x00
.db 0x02
.db 0x00
.db 0xff
r7:
.ds 4
