前回までにLCDに時刻表示ができましたが、2行目の欄が空いているので温湿度表示を追加したいと思います。
温湿度のセンサーは、以前Ａｒｄｕｉｎｏに接続したＡＭ２３２１を使用したいと思います。
ＡＭ２３２１はｉ２ｃによって接続されますので、ＬＣＤ i/f及びＲＴＣに並列接続となります。
前回のａｒｄｕｉｎｏのデータの読み込み手順に沿ってソフトを作成していきたいと思います。
ＡＭ２３２１のスレーブアドレスは、前回確認している Ｏｘ５Ｃです。
まずは、眠っているＡＭ２３２１を起こしに行きます。
ダミーの０ｘ００を書き込みに行きますが、眠っているので、応答としてＮＡＣＫが帰ってきます。
これまでのｉ２ｃのプログラムであれば、端末にｅｒｒ表示をして先に進んでくれません。
ということで、ＮＡＣＫが帰ってきたら強制的にＳＴＯＰモードにして、待機状態に戻してあげます。
変更した部分のi2c_writeのプログラムは次の通りとなります。
ld a,0xc4 ;;Slave recciver mode
out0 (I2CCON),a ;; AA=1 ENSIO=1 SI=0
i2c_w_loop2:
in0 a,(I2CCON) ;; SI=1 ?
bit 3,a
jr z,i2c_w_loop2
in0 a,(I2CSTA) ;;Poll from transmission finished
cp 0x20 ;;Write data N-ACK
jr z,data_w_stop ;;go to Stop mode
cp 0x18
jr nz,err次に １ｍｓ待った後に、データ読み込み命令を書き込みします。
この命令は、 スレーブアドレス＋Ｗ＋ＤＡＴＡ＋ＤＡＴＡ＋ＤＡＴＡと複数のデータを書き込みする必要がありますので、従来のｉ２ｃ＿ｗｒｉｔｅに対して、複数のデータを書き込み可能な、ｉ２ｃ＿ｂｕｆｆ＿ｗｒｉｔｅを新たに作成しました。
ＨＬレジスタに書き込むデータのｂｕｆｆアドレスを設定します。
Ｂレジスタには書き込むデータのバイト数
Ｅレジスタにはスレーブアドレスを設定します。
実際のプログラムは次のようになります。
i2c_buff_write: ;;write buff data >> HL reg
;;write buff size >> B reg
;;slave address >> E reg
ld a,0xe4 ;;Slave recciver mode
out0 (I2CCON),a ;; AA=1 ENSIO=1 STA=1
i2c_bw_loop1:
in0 a,(I2CCON) ;; SI=1 ?
bit 3,a
jr z,i2c_bw_loop1
in0 a,(I2CSTA) ;;Poll from transmission finished
cp 0x08
jp nz,err
in a,(I2CDAT)
ld a,e ;;Slave address set
sla a
out0 (I2CDAT),a
ld a,0xc4 ;;Slave recciver mode
out0 (I2CCON),a ;; AA=1 ENSIO=1 SI=0
i2c_bw_loop2: in0 a,(I2CCON) ;; SI=1 ?
bit 3,a
jr z,i2c_bw_loop2
in0 a,(I2CSTA) ;;Poll from transmission finished
cp 0x20 ;;Write data N-ACK
jr z,data_bw_stop ;;go to Stop mode
cp 0x18
jr nz,err
;; HL reg = buffer adress
i2c_bw_next: ;; end buffer is "00
ld a,(hl) ;; write data Areg is I2CDAT
out0 (I2CDAT),a
ld a,0xc4 ;;Slave recciver mode
out0 (I2CCON),a ;; AA=1 ENSIO=1 SI=0
i2c_bw_loop3:
in0 a,(I2CCON) ;; SI=1 ?
bit 3,a
jr z,i2c_bw_loop3
in0 a,(I2CSTA) ;;Poll from transmission finished
cp 0x28
jr nz,err
inc hl
djnz i2c_bw_next
data_bw_stop:
ld a,0xD4 ;;Generate STOP mode
out0 (I2CCON),a ;; AA=1 ENSIO=1 SI=0
D_bW_ST0:
in0 a,(I2CCON) ;; STO=0 ?
bit 4,a
jr nz,D_bW_ST0
in a,(I2CSTA)
cp 0xf8
jr nz,err
retこのｉ２ｃ＿ｂｕｆｆ＿ｗｒｉｔｅを使って書き込むデータは次のようになります。
０ｘ０３：レジスターを読み込む指令
０ｘ００：レジスターのスタートアドレスは ０ｘ００から
０ｘ０４：レジスターの読み込み個数は ４レジスター
続いて、２ｍＳ後に
ＡＭ２３２１の温湿度データを読みに行きます。
ここでも、複数のデータを読み込みに行かなくていけませんので、従来のｉ２ｃ＿ｒｅａｄに対して、複数データ読み込み可能なｉ２ｃ＿ｂｕｆｆ＿ｒｅａｄを新たに作成しました。
ＨＬレジスタに読み込んだデータを格納するｂｕｆｆアドレスを設定します。
Ｂレジスタには読み込むデータのバイト数
Ｅレジスタにはスレーブアドレスを設定します。
実際のプログラムは次のようになります。
i2c_buff_read: ;;buff >> HL reg
;;buff size >> B reg
;;Slave Address C reg
ld a,0xe4 ;;Master Receiver Mode
out0 (I2CCON),a ;; AA=1 ENSIO=1 STA=1
i2c_br_si01:
in0 a,(I2CCON) ;; SI=1 ?
bit 3,a
jr z,i2c_br_si01
in0 a,(I2CSTA) ;;Poll from transmission finished
cp 0x08
jp nz,i2c_br_err
in0 a,(I2CDAT)
ld a,e ;read slave address d reg
scf ;set read mode bit0=1
RLA
out0 (I2CDAT),a ;set slave address
ld a,0xc4 ;send data
out0 (I2CCON),a
i2c_br_si06:
in0 a,(I2CCON)
bit 3,a ;SI=1 ?
jr z,i2c_br_si06
in0 a,(I2CSTA) ;Address+R has been transmitted
cp 0x40 ;ACK has been received
jr nz,i2c_br_err
dec b
jr z,i2c_br_next_end
i2c_br_next:
ld a,0xc4 ;Reset SI And AA bit
out0 (I2CCON),a ;AA=0 ENSIO=1 STA=0 STO=0
i2c_br_si07:
in0 a,(I2CCON)
bit 3,a ;SI=1 ?
jr z,i2c_br_si07
in0 a,(I2CSTA) ;Data has been received
cp 0x50 ;data-ACK has been returned
jr nz,i2c_br_err
in0 a,(I2CDAT) ;Received Data read a reg
ld (HL),a
inc hl
djnz i2c_br_next
i2c_br_next_end:
ld a,0x44 ;Reset SI And AA bit
out0 (I2CCON),a ;AA=0 ENSIO=1 STA=0 STO=0
i2c_br_si08:
in0 a,(I2CCON)
bit 3,a ;SI=1 ?
jr z,i2c_br_si08
in0 a,(I2CSTA) ;Data has been received
cp 0x58 ;data-ACK has been returned
jr nz,i2c_br_err
in0 a,(I2CDAT) ;Received Data read a reg
ld (HL),a
ld a,0xd4 ;Generate STOP command
out (I2CCON),a ;AA=1 ENSIO=1 STA=0 STO=1
i2c_br_stop_loop:
in0 a,(I2CCON)
bit 4,a ;STO=0 ?
jr nz,i2c_br_stop_loop
in0 a,(I2CSTA)
cp 0xf8 ;reset or STOP command
jr nz,i2c_br_err
xor a
retこのｉ２ｃ＿ｂｕｆｆ＿ｒｅａｄにより ８バイトのデータを読み込みます。
０ｘ０３：レジスターを読み込みます
０ｘ０４：４つのレジスター内容を４バイトで返します。
０ｘ？？：湿度の高位バイトを返します
０ｘ？？：湿度の低位バイトを返します
０ｘ？？：温度の高位バイトを返します
０ｘ？？：温度の低位バイトを返します
０ｘＣＲＣ１： ＣＲＣを２バイトに分けて返します
０ｘＣＲＣ２：
読み込んだデータをＬＣＤに表示していきますが、紙面が長くなるので次回に分けたいと思います。
