最初にシリアルポートの確認を行っていきます。今回の回路では、チェンネル０のみ使用します。
シリアルクロックは、システムクロックからも生成できますが、いままでのZ80ボードと同じように、外部クロックにします。
ボーレートは、19200bps で8ビット、ストップ 1ビット、ノンパリティー（８１N)です。
CNTLA０レジスタで、Rｘ・Txを有効にし、通信条件の８１Nを設定します。
CNTLB０レジスタで、外部クロックを選択します。
STAT０レジスタの1ビット目で送信可、7ビット目で受信可の条件を確認します。
TDR０レジスタで送信データを、RDR０レジスタで受信データを取得します。
下記のプログラムは、改行したのち、OKの文字を出力し、改行の後、入力された文字をエコーバックします。
; HD64180 serial communication test
; rom 0000h -- 7fffh
; ram 8000h -- ffffh(MMU setting)
; External clock 16MHz
; assembler
; program start 0000H
; main 0100H
; HD64180 serial communication (Ch0)
; extemal Clock 307.2KHz(4.9152MHz TC74HC4040 1/16 Frequency division)
; Band Rate:19200 8bits 1Stopbits none Parity (81N)
;
;
; assemblers ASxxxx and ASlink V5.10
; file name com0_test.asm
; $ asz80 -l -s -o com0_test.asm
; $ aslink -i com0_test
; win10 writer (TL866(2)PLUS com0_test.ihx
.hd64
.area TEST(ABS)
TDR0 .equ 0x06 ;ch0 serial
RDR0 .equ 0x08
STAT0 .equ 0x04
CNTLA0 .equ 0x00
CNTLB0 .equ 0x02
;TDR1 .equ 0x07 ;ch1 serial
;RDR1 .equ 0x09
;STAT1 .equ 0x04
;CNTLA1 .equ 0x01
;CNTLB1 .equ 0x03
CBR .equ 0x38 ;i/o setting reg
BBR .equ 0x39
CBAR .equ 0x3a
ram .equ 0x20 ;ram address 0x20000
cbar_set .equ 0x88 ;moni move temprary CBAR setting address 0x8000
.org 0x0000
jp init_ram
.org 0x0080
init_ram:
ld a,cbar_set ;ram 0x8000 to 0xffff
out0 (CBAR),a
ld a,ram
out0 (BBR),a
out0 (CBR),a
jp start
.org 0x0100
start: ld sp,0x0000
call com_init
ld a,0x0d
call putchar
ld a,"O"
call putchar
ld a,"K"
call putchar
ld a,0x0d
call putchar
loop1: call getchar
call putchar
jr loop1
putchar:push af ;ch0 seriai output
com_out:in0 a,(STAT0)
bit 1,a ;Tx data Empty ?
jr z,com_out
pop af
out0 (TDR0),a
ret
getchar:in0 a,(STAT0)
rlca ;Rx data Full ?
jr nc,getchar
in0 a,(RDR0)
ret
com_init: ;serial communication Initialize
push af
ld a,0x64 ;ch0
out0 (CNTLA0),a ;Rx/Tx Enable,8bit/1stop bit/non parity
ld a,0x07
out0 (CNTLB0),a ;External input clock (307.2KHz 1/16 19200pbs)
; ld a,0x64 ;ch1
; out0 (CNTLA1),a ;Rx/Tx Enable,8bit/1stop bit/non parity
; ld a,0x07
; out0 (CNTLB1),a ;External input clock (307.2KHz 1/16 19200pbs)
pop af
ret
シリアル通信もできるようになりましたので、これまでのZ80ボードと同じように６４K化モニタを組み込んでみたいと思います。
８２５５を使用したSDCARDへのSPI通信は、Z８０＋８２５１＋８２５５でのモニタプログラムと同じなので、割愛します。
６４K化モニタに切り替えるTコマンドは次のように、行っています。
ステップ１：ROMのモニタを上位RAM(0x8000～0xffff）に一時的にコピーする。(コピー先先頭アドレス0x8000）。
tコマンドの該当部分のプログラムは次のようになります。
trance:
call call_yes_msg
call getchar
cp "y"
jr nz,crret_t
call cr
ld a,cbar_set ;ram 0x8000 to 0xffff
out0 (CBAR),a
ld a,ram
out0 (BBR),a
out0 (CBR),a
ld hl,0x0000 ;moni copy at temp_addr
ld de,temp_addr
ld bc,prog_end
ldir
ld hl,move_prog+temp_addr
jp (hl) ;temprary address jumpステップ２：0x8000にコピーしたｔコマンドのプログラムに実行を移し、ROMをRAMに切り替え（CBARレジスターに0x00を書き込む）、0x8000からのモニタをRAM上の0x0000から始まるアドレスにコピーする。コピーが完了したら、RAM上のモニタのtコマンドのプログラムに制御を移す。
該当のプログラムは次のようになります。
move_prog:
xor a ;ram 0x0000 to 0x7fff setting
out0 (CBAR),a
ld hl,temp_addr ;moni moveing at ram 0x0000 to prog_end
ld de,0x0000
ld bc,prog_end
ldir
ld hl,go_moni
jp (hl) ;ram monitor jumpステップ３：メモリウェイトを０に、I/Oウェイトも０にして、モニタをスタートする。（Z8S180固有のCMR、CCRレジスタはコメントしています）
go_moni:
ld sp,0x8000
; in0 a,(CMR) ;XTAL*2
; set 7,a
; out0 (CMR),a
; in0 a,(CCR) ;XTAL/1
; set 7,a
; out0 (CCR),a
in0 a,(DCNTL)
res 7,a ;MWI1=0
res 6,a ;MWI0=0 Memory wait state =0
res 5,a ;IWI1=0
res 4,a ;IWI0=0 I/O wait state =1
out0 (DCNTL),a
nop
nop
jp start実際にモニタを実行してみました。
ROMのモニタ上でtコマンドを実行して、RAM上でのモニタに制御を移し、RAM領域の0x0003を書き換えしてみました。
Monitor HD64180 CPU ver0.73(spi) by Pinecone 2020/12/10
BBR:20 CBR:20 CBAR:88
wait memory:3 wait i/o:4
monitor area:0100-0A7E
>t Yes:
Monitor HD64180 CPU ver0.73(spi) by Pinecone 2020/12/10
BBR:20 CBR:20 CBAR:00
wait memory:0 wait i/o:0
monitor area:0100-0A7E
>d 0000
addr +0 +1 +2 +3 +4 +5 +6 +7 +8 +9 +A +B +C +D +E +F
0000 C3 80 00 FF FF FF FF FF FF FF FF FF FF FF FF FF
>m 0003 FF 77
>d 0000
addr +0 +1 +2 +3 +4 +5 +6 +7 +8 +9 +A +B +C +D +E +F
0000 C3 80 00 77 FF FF FF FF FF FF FF FF FF FF FF FF
>?
Monitor HD64180 CPU ver0.73(spi) by Pinecone 2020/12/10
Help menu
? Help
d memory dump
m memory change address old new
l hex file load
j jump
i i/o register i/o-address old new
c call
t ram area trance monitor jump
ai spi(sd-card) Initialization
ar spi(sd-card) read (512byte/block) 0x0000-0xffff set
aw spi(sd-card) write (512byte/block) 0x0000-0xffff set
>全体のモニタソースプログラムは下記の通りです。（ちょっと長いです）
; HD64180 monitor ver0.73(spi) by Pinecone 2020/12/10
;
; HD64180 cpu
; rom 0000h -- 7fffh
; ram 8000h -- ffffh(MMU setting)
; External clock 16MHz
; HD64180 serial communication (Ch0)
; extemal Clock 307.2KHz(4.9152MHz TC74HC4040 1/16 Frequency division)
; Band Rate:19200 8bits 1Stopbits none Parity (81N)
;
; assembler
; program start 0000H
; main 0100H
;
; assemblers ASxxxx and ASlink V5.10
; file name HD64180_moni073_spi.asm
; $ asz80 -l -s -o HD64180_moni073_spi.asm
; $ aslink -i HD64180_moni073_spi
; win10 rom-writer TL866(2)PLUS HD64180_moni073_spi.ihx
;
.hd64
.area TEST(ABS)
;;spi i/o port setting
;;8255 Parallel port
PPIA .equ 0x80 ;PPI-A PORT DATA REG
PPIB .equ 0x81 ;PPI-B PORT DATA REG
PPIC .equ 0x82 ;PPI-C PORT DATA REG
PPICNT .equ 0x83 ;PPI CONTL REG
;OUTPUT-PORT
S_DI .equ 7 ;0b10000000 D7
S_CS .equ 6 ;0b01000000 D6
S_CLK .equ 5 ;0b00100000 D5
;INPUT-PORT
DO .equ 0 ;0b10000000 D0
TDR0 .equ 0x06 ;ch0 serial
RDR0 .equ 0x08
STAT0 .equ 0x04
CNTLA0 .equ 0x00
CNTLB0 .equ 0x02
;TDR1 .equ 0x07 ;ch1 serial
;RDR1 .equ 0x09
;STAT1 .equ 0x04
;CNTLA1 .equ 0x01
;CNTLB1 .equ 0x03
CBR .equ 0x38 ;i/o setting reg
BBR .equ 0x39
CBAR .equ 0x3a
;CMR .equ 0x1e
;CCR .equ 0x1f
DCNTL .equ 0x32
ram .equ 0x20 ;ram address 0x20000
cbar_set .equ 0x88 ;moni move temprary CBAR setting address 0x8000
temp_addr .equ 0x8000 ;moni move temprary address
.org 0x0000
jp ram_setting
.org 0x0080
ram_setting:
ld a,cbar_set ;z80 ram address 0x8000 to 0xffff set cbar_set:0x88
out0 (CBAR),a
ld a,ram ;mmu ram address 0x20000 set ram:0x20
out0 (BBR),a
out0 (CBR),a
jp start
.org 0x0100
start: ;cold start
ld sp,0x0000 ;stack pointer set
call com_init ;serial channel initialize
call ppi_init ;Parallel port A initialize
call cr
ld hl,msg_op ;opening message display
call msgout
call cpu_msg1
call cpu_msg2
call moni_area
prompt: ld a,">" ;main routine
call putchar ;prompt display
call getchar
call putchar
cp "?" ;help ?
call z,help
cp "d" ;memory disply?
call z,dump
cp "m" ;memory rewrite ?
call z,memory
cp "l" ;hex file load?
call z,loadhex
cp "j" ;address jump?
call z,jump
cp "i" ;i/o register rewite
call z,ioreg
cp "c"
call z,calling ;address call
cp "t"
call z,trance ;moni 64Kmemory trance
cp "a"
call z,spi_card ;read/write spi sd-card
cp 0x0d
jr z,prompt
cp 0x00
jr z,prompt
call cr
jr prompt
help: call cr
ld hl,msg_op ;help ?
call msgout
ld hl,help_msg
call msgout
ret
cr:
ld a,0x0d
call putchar
ret
crret_t:
call cr
ret
trance:
call call_yes_msg
call getchar
cp "y"
jr nz,crret_t
call cr
ld a,cbar_set ;ram 0x8000 to 0xffff
out0 (CBAR),a
ld a,ram
out0 (BBR),a
out0 (CBR),a
ld hl,0x0000 ;moni copy at temp_addr
ld de,temp_addr
ld bc,prog_end
ldir
ld hl,move_prog+temp_addr
jp (hl) ;temprary address jump
;
move_prog:
xor a ;ram 0x0000 to 0x7fff setting
out0 (CBAR),a
ld hl,temp_addr ;moni moveing at ram 0x0000 to prog_end
ld de,0x0000
ld bc,prog_end
ldir
ld hl,go_moni
jp (hl) ;ram monitor jump
;
go_moni:
ld sp,0x8000
; in0 a,(CMR) ;XTAL*2
; set 7,a
; out0 (CMR),a
; in0 a,(CCR) ;XTAL/1
; set 7,a
; out0 (CCR),a
in0 a,(DCNTL)
res 7,a ;MWI1=0
res 6,a ;MWI0=0 Memory wait state =0
res 5,a ;IWI1=0
res 4,a ;IWI0=0 I/O wait state =1
out0 (DCNTL),a
nop
nop
jp start
cpu_msg1:
ld hl,cpu_msg_bbr ;BBR reg disply
call msgout
in0 a,(BBR)
call hex_a_disp
ld hl,cpu_msg_cbr ;CBR reg disply
call msgout
in0 a,(CBR)
call hex_a_disp
ld hl,cpu_msg_cbar ;CBAR reg disply
call msgout
in0 a,(CBAR)
call hex_a_disp
call cr
ret
cpu_msg2:
; ld hl,cpu_msg_clock ;clock divide
; call msgout
; in0 a,(CCR)
; rlca
; jr c,clock1
; ld a,"2"
; jr cpum1
;clock1: ld a,"1"
;cpum1:
; call putchar
; ld hl,cpu_msg_speed ;*2 Clock Multiplier
; call msgout
; in0 a,(CMR)
; rlca
; jr c,speed1
; ld a,"1"
; jr cpum2
;speed1: ld a,"2"
;cpum2:
; call putchar
ld hl,cpu_msg_wait_m ;Memory Wait State
call msgout
in0 a,(DCNTL)
rlca
rlca
and 0x03
add a,0x30
call putchar
ld hl,cpu_msg_wait_io ;i/o Wait State
call msgout
in0 a,(DCNTL)
rlca
rlca
rlca
rlca
and 0x03
cp 0x00
jr nz,iowait1
add a,0x30
jr iowait0
iowait1:
add a,0x31
iowait0:
call putchar
call cr
ret
moni_area:
ld hl,moni_area_msg ;monitor area
call msgout
ld hl,start
ld a,h
call hex_a_disp
ld a,l
call hex_a_disp
ld a,"-"
call putchar
ld hl,prog_end
ld a,h
call hex_a_disp
ld a,l
call hex_a_disp
call cr
ret
jump: ;address jump?
ld a," "
call putchar
call input_hl ;dump address input
cp 0x00
jr nz,crret
call call_yes_msg
call getchar
cp "y"
jr nz,crret
call cr
jp (HL)
crret:
call cr
ret
calling: ;address call?
ld a," "
call putchar
call input_hl ;call address input
cp 0x00
jr nz,crret
call call_yes_msg
call getchar
cp "y"
jr nz,crret
call cr
ld de,callret
push de
jp (HL)
callret:
ret
call_yes_msg:
push hl
ld hl,yes_msg
call msgout
pop hl
ret
loadhex:
call loadhexline ;load 1line Hex file
cp 0xff ;hex file read err
jr z,loadhexerr
cp 0x01 ;hex file end?
jr nz,loadhex
call cr
ld hl,ok_msg
call msgout
ret
loadhexerr:
call cr ;hex file read skipret
ld hl,err_msg
call msgout
ret
loadhexline:
ld a,0x0d
call putchar
ld d,0x00 ;checksum count clr
call getchar ;record mark is ":"
cp ":"
jr nz,loadhexlineerr
call input_l ;data size 1byte
ld b,l ;checksum = checksum + data size
ld a,d
add b
ld d,a
call input_hl ;offset address 2byte
push hl
pop ix ;offset address HLreg >> IXreg
ld a,d ;checksum = checksum + address Low
add l
add h ;checksum = checksum + address Hi
ld d,a
call input_l ;record type
ld a,l
cp 0x00 ;data record
jr nz,checkrecord
;; *** data record job ****
data_hex:
call input_l ;read hex 1byte in Lreg(hex)
ld (ix),l ;offset address < hex data
inc ix ;offset address +1
ld a,l
add d ;cheksum Dreg = Dreg + Lreg
ld d,a
djnz data_hex ;Breg(data size) == 0?
call input_l ;chechsum OK?
ld a,d
add l
cp 0x00
jr nz,loadhexlineerr
call getchar
cp 0x0a ;load 1line hex LF?
jr nz,loadhexlineerr
ld a,0x00
ret
checkrecord: ;end record ?
cp 0x01
jr nz,loadhexlineerr
call input_l
ld a,l
cp 0xff
jr nz,loadhexlineerr
ld a,0x01
ret
loadhexlineerr:
ld a,0xff ;read record err (no support)
ret
dump: ;memory dump
ld a," "
call putchar
call input_hl ;dump address input
cp 0x00
jr z,dump1
push iy ;memory dump address set
pop hl
dump1:
call dump_hl ;memory dump
push hl ;memory address IY set
pop iy
ret
memory: ;memory change
ld a," " ;space
call putchar
call input_hl ;change memory address
cp 0x00
jr z,memory1 ;no address hex code
ld a,0x0d
call putchar
ret
memory1:
ld a," " ;current memory display
call putchar
ld a,(HL)
call hex_a_disp
ld a," "
call putchar
push hl
call input_l ;new memory conntents input
cp 0x00
jr z,memory2
pop hl
xor a
ret
memory2:
ld c,l ;memory contents update
pop hl
ld (hl),c
ld a,0x0d
call putchar
ret
ioreg: ;ioreg change
ld a," " ;space
call putchar
call input_l ;change i/o register
cp 0x00
jr z,ioreg1 ;no address hex code
ld a,0x0d
call putchar
ret
ioreg1:
ld a," " ;current memory display
call putchar
ld b,0x00
ld c,l
in a,(c)
call hex_a_disp
ld a," "
call putchar
call input_l ;new memory conntents input
cp 0x00
jr z,ioreg2
xor a
ret
ioreg2:
ld a,l ;memory contents update
out (c),a
ld a,0x0d
call putchar
ret
spi_card:
call getchar
cp "i"
call z,spi_init
cp "r"
call z,spi_read
cp "w"
call z,spi_write
ret
spi_read:
ld hl,read_block_no_msg
call msgout
call input_hl
cp 0x00
jr z,spi_read1
call cr
xor a
ret
spi_read1:
ld a,(r7)
bit 6,a
jp z,read_SD_ver2
ld a,h ;SDHC
ld (cmd17+03),a
ld a,l
ld (cmd17+04),a
jr spi_read2
read_SD_ver2:
ld a,h ;Ver2
ld (cmd17+02),a
ld a,l
ld (cmd17+03),a
spi_read2:
ld hl,save_addr_msg
call msgout
call input_hl
cp 0x00
jr z,cmd17_out
call cr
xor a
ret
cmd17_out:
call call_yes_msg
call getchar
cp "y"
jp nz,spi_ret
push hl
call dummy_data ;dummy data(0xff) out
ld hl,cmd17
call cmd_out ;cmd17 Issue
call r1_resp
cp 0x00 ;response is 0x00 read mode OK?
jp nz,init_err
cmd17_st:
call r1_resp ;read data start response?
cp 0xfe ;data start byte 0xfe?
jr nz, cmd17_st
ld b,0x00 ;read data size 256byte
pop hl ;read data buff address
cmd17_r:
call resp ;read data
ld (hl),a
inc hl
djnz cmd17_r
ld b,0x00
cmd17_r2:
call resp
ld (hl),a ;read data
inc hl
djnz cmd17_r2
call resp ;crc Skipping read
call resp ;crc Skipping read
ld d,0xff ;dummy data 0xff(cs low)
call spi_8bit
;memory dump address
ld bc,0x0200
sbc hl,bc
;memory dump 512b
ld a,0x0d
call putchar
call hl_disp256 ;256bye dump
call putchar
call hl_disp256 ;256bye dump
call putchar
xor a
ret
hl_disp256:
push bc
ld b,0x00 ;dump data size 256bye
push hl
ld hl,dump_msg ;dump address msg output
call msgout
pop hl
ld a,h ;dump address HLreg
call hex_a_disp ;dump address output
ld a,l
call hex_a_disp
ld a," "
call putchar
call putchar
hl_disp256_loop:
ld a,(HL) ;dump addres data (HL)
inc HL
call hex_a_disp
ld a,b
cp 0x01 ;end dump size?
jr z,hl_disp256_loop1
ld a,b
and 0x0f
cp 0x01 ;0x?0-0x?f is 0x01(1line disp end?)
jr z,hl_disp256_cr
ld a," " ;space Insert
call putchar
jr hl_disp256_loop1
hl_disp256_cr:
ld a,0x0d
call putchar
ld a,h ;dump address HLreg
call hex_a_disp ;dump address output
ld a,l
call hex_a_disp
ld a," "
call putchar
call putchar
hl_disp256_loop1:
djnz hl_disp256_loop
ld a,0x0d
call putchar
pop bc
ret
spi_write:
ld hl,write_block_no_msg
call msgout
call input_hl
cp 0x00
jr z,spi_write1
call cr
xor a
ret
spi_write1:
ld a,(r7)
bit 6,a
jp z,write_SD_ver2
ld a,h ;SDHC
ld (cmd24+03),a
ld a,l
ld (cmd24+04),a
jr spi_write2
write_SD_ver2: ;Ver2
ld a,h
ld (cmd24+02),a
ld a,l
ld (cmd24+03),a
spi_write2:
ld hl,write_addr_msg
call msgout
call input_hl
cp 0x00
jr z,cmd24_out
call cr
xor a
ret
cmd24_out:
call call_yes_msg
call getchar
cp "y"
jp nz,spi_ret
push hl
call dummy_data
ld hl,cmd24
call cmd_out
call r1_resp
cp 0x00
jp nz,init_err
ld d,0xfe
call spi_8bit
pop hl
ld b,0x00
cmd24_w:
ld d,(hl)
inc hl
call spi_8bit
djnz cmd24_w
ld b,0x00
cmd24_w2:
ld d,(hl)
inc hl
call spi_8bit
djnz cmd24_w2
ld d,0xff
call spi_8bit ;crc
call spi_8bit ;crc
call r1_resp
and 0x0f
cp 0x05
jp nz,init_err
cmd24_wch:
call r1_resp
cp 0x00
jr z,cmd24_wch
call dummy_data
ld bc,0x0200
sbc hl,bc
;memory dump 512b
ld a,0x0d
call putchar
call hl_disp256 ;256bye dump
call putchar
call hl_disp256 ;256bye dump
call putchar
xor a
ret
spi_init:
ld hl,spi_init_msg
call msgout
call call_yes_msg
call getchar
cp "y"
jp nz,spi_ret
call cr
call spi_card_init
ld hl,ok_msg
call msgout
ret
spi_card_init:
xor a
set S_CS,a ;CS="H"
set S_DI,a ;DI="H"
out0 (PPIC),a
ld b,80 ;80 clok output
call loopspii
xor a
out (PPIC),a ;CS="L" DI="L" CLK="L"
call cmd0_out
cp 0x01
jp nz,init_err
call cmd8_out
cp 0x01
jp nz,init_err
call cmd55_out
cp 0x01
jp nz,init_err
call acmd41_out
call cmd58_out
ld a,(r7)
bit 7,a
jp z,init_err
bit 6,a
jr z,SD_ver2
ld hl,sdhc_msg
init_msg:
call msgout
ret
SD_ver2:
ld hl,sd_ver2_msg
jr init_msg
cmd0_out:
ld hl,cmd0
call cmd_out
call r1_resp
push af
ld hl,cmd0_msg
call msgout
pop af
push af
call hex_a_disp
ld a,0x0d
call putchar
pop af
ret
cmd0_msg:
.str "CMD0:"
.db 0x00
cmd8_out:
call dummy_data
ld hl,cmd8
call cmd_out
call r1_resp
cp 0x01
ret nz
ld b,4
ld hl,r7
cmd8_r:
call resp
ld (hl),a
inc hl
djnz cmd8_r
cmd8_r_d:
ld hl,cmd8_msg
call msgout
ld a,0x01
call hex_a_disp
ld hl,r7
ld b,4
cmd8_r_d_loop:
ld a,(hl)
call hex_a_disp
inc hl
djnz cmd8_r_d_loop
ld a,0x0d
call putchar
ld a,0x01
ret
cmd8_msg:
.str "CMD8:"
.db 0x00
cmd55_out:
call dummy_data
ld hl,cmd55
call cmd_out
call r1_resp
push af
ld hl,cmd55_msg
call msgout
pop af
push af
call hex_a_disp
ld a,0x0d
call putchar
pop af
ret
cmd55_msg:
.str "CMD55:"
.db 0x00
acmd41_out:
call dummy_data
ld hl,acmd41 ;sd-card Initialize
call cmd_out
call r1_resp
cp 0x00
push af
ld hl,acmd41_msg
call msgout
pop af
push af
call hex_a_disp
ld a,0x0d
call putchar
pop af
ret z
call cmd55_out
jr acmd41_out
acmd41_msg:
.str "ACMD41:"
.db 0x00
spi_ret:
call cr
ret
init_err:
ld hl,spi_init_err_msg
call msgout
call cr
jp start
cmd58_out:
call dummy_data
ld hl,cmd58
call cmd_out
call r1_resp
push af
ld b,4
ld hl,r7
cmd58_r:
call resp
ld (hl),a
inc hl
djnz cmd58_r
cmd58_r_d:
ld hl,cmd58_msg
call msgout
pop af
push af
call hex_a_disp
ld hl,r7
ld b,4
cmd58_r_d_loop:
ld a,(hl)
call hex_a_disp
inc hl
djnz cmd58_r_d_loop
ld a,0x0d
call putchar
pop af
ret
cmd58_msg:
.str "CMD58:"
.db 0x00
dummy_data:
xor a
set S_CS,a ;CS="H"
set S_DI,a ;DI="H"
out0 (PPIC),a
ld b,8 ;1clok output
call loopspii
xor a
out0 (PPIC),a
ret
loopspii:
res S_CLK,a ;CLK L
out0 (PPIC),a
nop
nop
nop
nop
nop
nop
nop
nop
set S_CLK,a ;CLK H
out0 (PPIC),a
nop
nop
nop
nop
nop
djnz loopspii
ret
r1_resp:
call resp
cp 0xff
jr z,r1_resp
ret
resp:
ld d,0xff
call spi_8bit
ld a,e
ret
cmd_out: ;command out
push hl
push bc
ld b,0x06 ;command line word count
cmd_out1:
ld d,(hl) ;command line area
call spi_8bit
inc hl
djnz cmd_out1
pop bc
pop hl
ret
spi_8bit: ;outdata Dreg,inputdata Ereg
push bc
ld c,0x00
ld b,0x08
loopspi:
xor a
rlc d
rra
res S_CLK,a ;CLK L
out0 (PPIC),a
nop
nop
nop
nop
nop
nop
set S_CLK,a ;CLK H
out0 (PPIC),a
in0 a,(PPIC)
rrca
rl e
djnz loopspi
xor a
out0 (PPIC),a
pop bc
ret
input_l: ;input Lreg hex (1byte)
push bc
ld b,0x02
jr input_loop
input_hl: ;input HLreg hex (2byte)
push bc
ld b,0x04
input_loop:
ld hl,0x0000 ;HL reg cler
jr input_hl2
shift_hl:
add hl,hl ;HL reg shift left 4bit
add hl,hl
add hl,hl
add hl,hl
input_hl2:
call getchar ;input ascii hex 1char
call putchar
call ascii_hex ;ascii hex 1char >> Areg
cp 0xff
jr z,input_hl_err
and 0x0f ;Areg low order 4bit >> Lreg
or l
ld l,a
djnz shift_hl
input_hl_end:
pop bc
xor a ;OK >> Areg 0x00
ret
input_hl_err:
ld a,0xff ;NG >> Areg 0xff
pop bc
ret
dump_hl: ;memory dump 1line(+0 -- +f)
ld a,0x0d
call putchar
push hl
ld hl,dump_msg ;dump address msg output
call msgout
pop hl
ld a,h ;dump address HLreg
call hex_a_disp ;dump address output
ld a,l
call hex_a_disp
ld a," "
call putchar
call putchar
ld b,0x10 ;address --> address +0f
hl_disp:
ld a,(HL) ;dump addres data (HL)
inc HL
call hex_a_disp
ld a," "
call putchar
djnz hl_disp
ld a,0x0d
call putchar
ret
hex_a_disp: ;Areg(HEX) >> putchar(areg)
push af
rrca ;7-4bit Right shift
rrca
rrca
rrca
call hex_ascii ;3-0bit Hex >> Hex ascii(0-F)
call putchar ;7-4bit putchar
pop af
call hex_ascii ;3-0bit Hex >> Hex ascii(0-F)
call putchar ;3-0bit putchar
ret
ascii_hex:
sub 0x30
jr c,err_hex
cp 0x0A ;0-9
jr c,hex_1_9
sub 0x11
cp 0x06 ;A-F
jr c,hex_A_F
sub 0x20
cp 0x06 ;a-f
jr nc,err_hex
hex_A_F:
add 0x0a
hex_1_9:
ret
err_hex:ld a,0xff
ret
hex_ascii: ;Areg(HEX) >> Areg(ascii code)
and a,0x0f
cp 0x0a
jr c,ascii0_9
add 0x37
ret
ascii0_9:
add 0x30
ret
msgout:
ld a,(hl) ;(HL)reg is output disp at 0x00
cp 0x00
ret z
call putchar
inc hl
jr msgout
getchar:in0 a,(STAT0) ;ch0 serial input
rlca ;Rx data Full ?
jr nc,getchar
in0 a,(RDR0)
; call putchar1 ;ch0 serial monitor >> ch1 output
ret
putchar:push af ;ch0 seriai output
com_out:in0 a,(STAT0)
bit 1,a ;Tx data Empty ?
jr z,com_out
pop af
out0 (TDR0),a
ret
;getchar1:in0 a,(STAT1)
; rlca
; jr nc,getchar1
; in0 a,(RDR1)
; ret
;putchar1:push af
;com_out1:in0 a,(STAT1)
; bit 1,a
; jr z,com_out1
; pop af
; out0 (TDR1),a
; ret
com_init: ;serial communication Initialize
push af
ld a,0x64 ;ch0
out0 (CNTLA0),a ;Rx/Tx Enable,8bit/1stop bit/non parity
ld a,0x07
out0 (CNTLB0),a ;External input clock (307.2KHz 1/16 19200pbs)
; ld a,0x64
; out0 (CNTLA1),a
; ld a,0x07
; out0 (CNTLB1),a
pop af
ret
ppi_init:
ld a,0b10000001 ;PPIA mode0,output PPIB mode0,output
out (PPICNT),a ;PPIC C7-C4 output,C3-C0 input
ret
;
msg_op: .str "Monitor HD64180 CPU ver0.73(spi) by Pinecone 2020/12/10"
.db 0x0d
.db 0x00
help_msg:
.db 0x0d
.str "Help menu"
.db 0x0d
.db 0x0d
.str "? Help"
.db 0x0d
.str "d memory dump"
.db 0x0d
.str "m memory change address old new"
.db 0x0d
.str "l hex file load"
.db 0x0d
.str "j jump"
.db 0x0d
.str "i i/o register i/o-address old new"
.db 0x0d
.str "c call"
.db 0x0d
.str "t ram area trance monitor jump"
.db 0x0d
.str "ai spi(sd-card) Initialization"
.db 0x0d
.str "ar spi(sd-card) read (512byte/block) 0x0000-0xffff set"
.db 0x0d
.str "aw spi(sd-card) write (512byte/block) 0x0000-0xffff set"
.db 0x0d
.db 0x00
dump_msg:
.str "addr +0 +1 +2 +3 +4 +5 +6 +7 +8 +9 +A +B +C +D +E +F"
.db 0x0d
.db 0x00
yes_msg:
.str " Yes:"
.db 0x00
cpu_msg_cbr:
.str " CBR:"
.db 0x00
cpu_msg_bbr:
.str " BBR:"
.db 0x00
cpu_msg_cbar:
.str " CBAR:"
.db 0x00
cpu_msg_clock:
.str " clock:1/"
.db 0x00
cpu_msg_speed:
.str " speed:*"
.db 0x00
cpu_msg_wait_m:
.str " wait memory:"
.db 0x00
cpu_msg_wait_io:
.str " wait i/o:"
.db 0x00
moni_area_msg:
.str " monitor area:"
.db 0x00
ok_msg:
.str "OK"
.db 0x0d
.db 0x00
err_msg:
.str "ERR"
.db 0x0d
.db 0x00
read_block_no_msg:
.str " read block No:"
.db 0x00
write_block_no_msg:
.str " write block No:"
.db 0x00
save_addr_msg:
.str " save addr:"
.db 0x00
write_addr_msg:
.str " write addr:"
.db 0x00
spi_init_err_msg:
.str "Spi Init Err"
.db 0x0d
.db 0x00
sdhc_msg:
.str ":SDHC"
.db 0x0d
.db 0x00
sd_ver2_msg:
.str ":SD Ver2"
.db 0x0d
.db 0x00
spi_init_msg:
.str " spi(sd-card) Initialize :"
.db 0x00
cmd0: ;;48bit(6byte) Fixed length
.db 0x40 ;;command index
.db 0x00 ;;argument
.db 0x00 ;;argument
.db 0x00 ;;argument
.db 0x00 ;;argument
.db 0x95 ;;CRC
;cmd1:
; .db 0x41 ;;command init
; .db 0x00
; .db 0x00
; .db 0x00
; .db 0x00
; .db 0xf9 ;;CRC
cmd8:
.db 0x48
.db 0x00
.db 0x00
.db 0x01
.db 0xaa
.db 0x87
acmd41:
.db 0x69
.db 0x40
.db 0xff
.db 0x80
.db 0x00
.db 0xff
cmd58:
.db 0x7a
.db 0x00
.db 0x00
.db 0x00
.db 0x00
.db 0xff
cmd55:
.db 0x77
.db 0x00
.db 0x00
.db 0x00
.db 0x00
.db 0xff
cmd16:
.db 0x50
.db 0x00
.db 0x00
.db 0x00
.db 0x00
.db 0xff
cmd17:
.db 0x51
.db 0x00
.db 0x00
.db 0x00
.db 0x00
.db 0xff
cmd24:
.db 0x58
.db 0x00
.db 0x00
.db 0x00
.db 0x00
.db 0xff
prog_end:
r7:
.ds 4
.end
HEXファイルです。
:03000000C38000BA
:100080003E88ED393A3E20ED3939ED3938C300016B
:20010000310000CDBA07CDC707CD700121CC07CD9907CDCC01CDF401CD26023E3ECDAD0798
:20012000CDA307CDAD07FE3FCC6001FE64CC0903FE6DCC1F03FE6CCC9102FE6ACC4B02FE82
:2001400069CC5303FE63CC6902FE74CC7A01FE61CC8903FE0D28C4FE0028C0CD700118BB1E
:20016000CD700121CC07CD9907210608CD9907C93E0DCDAD07C9CD7001C9CD8802CDA30711
:20018000FE7920F2CD70013E88ED393A3E20ED3939ED3938210000110080017E0AEDB0215E
:2001A000A381E9AFED393A210080110000017E0AEDB021B601E9310080ED3832CBBFCBB776
:2001C000CBAFCBA7ED39320000C30001218909CD9907ED3839CD6007218309CD9907ED3826
:2001E00038CD6007218F09CD9907ED383ACD6007CD7001C921A909CD9907ED38320707E648
:2002000003C630CDAD0721B709CD9907ED383207070707E603FE002004C6301802C631CDC4
:20022000AD07CD7001C921C209CD99072100017CCD60077DCD60073E2DCDAD07217E0A7C16
:20024000CD60077DCD6007CD7001C93E20CDAD07CD0907FE00200ECD8802CDA307FE792065
:2002600004CD7001E9CD7001C93E20CDAD07CD0907FE0020F0CD8802CDA307FE7920E6CD6A
:200280007001118702D5E9C9E5217D09CD9907E1C9CDB002FEFF280EFE0120F5CD70012104
:2002A000D109CD9907C9CD700121D509CD9907C93E0DCDAD071600CDA307FE3A2048CD04F1
:2002C00007457A8057CD0907E5DDE17A858457CD04077DFE002020CD0407DD7500DD237DED
:2002E000825710F3CD04077A85FE002019CDA307FE0A20123E00C9FE01200BCD04077DFEDF
:20030000FF20033E01C93EFFC93E20CDAD07CD0907FE002803FDE5E1CD2F07E5FDE1C93E38
:2003200020CDAD07CD0907FE0028063E0DCDAD07C93E20CDAD077ECD60073E20CDAD07E529
:20034000CD0407FE002803E1AFC94DE1713E0DCDAD07C93E20CDAD07CD0407FE0028063EEE
:200360000DCDAD07C93E20CDAD0706004DED78CD60073E20CDAD07CD0407FE002802AFC904
:200380007DED793E0DCDAD07C9CDA307FE69CC2C05FE72CC9C03FE77CC8504C921DA09CDCB
:2003A0009907CD0907FE002805CD7001AFC93A7E0ACB77CAC0037C32750A7D32760A1808D2
:2003C0007C32740A7D32750A21FB09CD9907CD0907FE002805CD7001AFC9CD8802CDA307A5
:2003E000FE79C24606E5CD940621720ACDCF06CDC006FE00C24A06CDC006FEFE20F906009C
:20040000E1CDC806772310F90600CDC806772310F9CDC806CDC80616FFCDDD06010002ED8E
:20042000423E0DCDAD07CD3404CDAD07CD3404CDAD07AFC9C50600E5214609CD9907E17C40
:20044000CD60077DCD60073E20CDAD07CDAD077E23CD600778FE01282378E60FFE01280725
:200460003E20CDAD0718153E0DCDAD077CCD60077DCD60073E20CDAD07CDAD0710D13E0DB7
:20048000CDAD07C1C921EA09CD9907CD0907FE002805CD7001AFC93A7E0ACB77CAA9047C1B
:2004A000327B0A7D327C0A18087C327A0A7D327B0A21070ACD9907CD0907FE002805CD70E6
:2004C00001AFC9CD8802CDA307FE79C24606E5CD940621780ACDCF06CDC006FE00C24A061C
:2004E00016FECDDD06E106005623CDDD0610F906005623CDDD0610F916FFCDDD06CDDD0672
:20050000CDC006E60FFE05C24A06CDC006FE0028F9CD9406010002ED423E0DCDAD07CD3426
:2005200004CDAD07CD3404CDAD07AFC921330ACD9907CD8802CDA307FE79C24606CD7001DC
:20054000CD4A0521D109CD9907C9AFCBF7CBFFED39820650CDA606AFD382CD9005FE01C275
:200560004A06CDB205FE01C24A06CDF205FE01C24A06CD1806CD56063A7E0ACB7FCA4A0687
:20058000CB77280721220ACD9907C921290A18F7214E0ACDCF06CDC006F521AC05CD990722
:2005A000F1F5CD60073E0DCDAD07F1C9434D44303A00CD940621540ACDCF06CDC006FE0143
:2005C000C00604217E0ACDC806772310F921EC05CD99073E01CD6007217E0A06047ECD601A
:2005E000072310F93E0DCDAD073E01C9434D44383A00CD940621660ACDCF06CDC006F5216B
:200600001106CD9907F1F5CD60073E0DCDAD07F1C9434D4435353A00CD9406215A0ACDCFB6
:2006200006CDC006FE00F5213E06CD9907F1F5CD60073E0DCDAD07F1C8CDF20518DA414383
:200640004D4434313A00CD7001C921140ACD9907CD7001C30001CD940621600ACDCF06CD54
:20066000C006F50604217E0ACDC806772310F9218D06CD9907F1F5CD6007217E0A06047E62
:20068000CD60072310F93E0DCDAD07F1C9434D4435383A00AFCBF7CBFFED39820608CDA695
:2006A00006AFED3982C9CBAFED39820000000000000000CBEFED3982000000000010E7C9D0
:2006C000CDC806FEFF28F9C916FFCDDD067BC9E5C5060656CDDD062310F9C1E1C9C50E0069
:2006E0000608AFCB021FCBAFED3982000000000000CBEFED3982ED38820FCB1310E4AFEDA9
:200700003982C1C9C506021803C50604210000180429292929CDA307CDAD07CD7307FEFFC0
:200720002809E60FB56F10E9C1AFC93EFFC1C93E0DCDAD07E5214609CD9907E17CCD600757
:200740007DCD60073E20CDAD07CDAD0706107E23CD60073E20CDAD0710F43E0DCDAD07C925
:20076000F50F0F0F0FCD8D07CDAD07F1CD8D07CDAD07C9D6303813FE0A380ED611FE063808
:2007800006D620FE063003C60AC93EFFC9E60FFE0A3803C637C9C630C97EFE00C8CDAD0705
:2007A0002318F6ED38040730FAED3808C9F5ED3804CB4F28F9F1ED3906C9F53E64ED3900BC
:2007C0003E07ED3902F1C93E81D383C94D6F6E69746F722048443634313830204350552055
:2007E000766572302E37332873706929202062792050696E65636F6E6520323032302F3197
:20080000322F31300D000D48656C70206D656E750D0D3F202048656C700D6420206D656D8C
:200820006F72792064756D700D6D20206D656D6F7279206368616E676520202061646472B4
:20084000657373206F6C64206E65770D6C20206865782066696C65206C6F61640D6A20204F
:200860006A756D700D692020692F6F20726567697374657220202020692F6F2D616464722B
:20088000657373206F6C64206E65770D63202063616C6C0D74202072616D2061726561201E
:2008A0007472616E6365206D6F6E69746F72206A756D700D6169207370692873642D636184
:2008C00072642920496E697469616C697A6174696F6E0D6172207370692873642D63617283
:2008E00064292072656164202028353132627974652F626C6F636B292020307830303030F0
:200900002D307866666666207365740D6177207370692873642D63617264292077726974D8
:20092000652028353132627974652F626C6F636B2920203078303030302D30786666666646
:20094000207365740D006164647220202B30202B31202B32202B33202B34202B35202B36F1
:20096000202B37202B38202B39202B41202B42202B43202B44202B45202B460D00205965AC
:20098000733A00204342523A00204242523A0020434241523A0020636C6F636B3A312F0011
:2009A0002073706565643A2A002077616974206D656D6F72793A00207761697420692F6FDE
:2009C0003A00206D6F6E69746F7220617265613A004F4B0D004552520D0020726561642049
:2009E000626C6F636B204E6F3A0020777269746520626C6F636B204E6F3A00207361766579
:200A000020616464723A0020777269746520616464723A0053706920496E69742045727278
:200A20000D003A534448430D003A534420566572320D00207370692873642D636172642988
:200A400020496E697469616C697A65203A0040000000009548000001AA876940FF8000FF94
:1E0A60007A00000000FF7700000000FF5000000000FF5100000000FF5800000000FF93
:00000001FF
