Z8S180からTMPZ84C015と移植してきた最初のモニタを今回のZ80+8251+8255に移植していきたいと思います。

まずは、8251及び8255のポートの定義に変更します。

;;8251
USARTD	.equ	0x84	;USART DATA REG
USARTC	.equ	0x85	;USART CONTL REG

;;8255
PPIA 		.equ 	0x88		;PPI-A PORT DATA REG
PPIB		.equ	0x89		;PPI-B PORT DATA REG
PPIC		.equ	0x8a		;PPI-C PORT DATA REG
PPICNT		.equ	0x8b		;PPI  CONTL REG

同様に8251と8255の初期化ルーチンを変更します。

        call    usart_init      ;serial channel initialize
	call	ppi_init	;Parallel port  initialize
・
中略
・
usart_init:
	xor	a
	ld	b,3
usartinit01:
	out	(USARTC),a		;dummy command
	djnz	usartinit01
	ld	a,0b01000000		;reset commmand 
	out	(USARTC),a
	ld	a,0b01001110		;1 stop bit,Parity disble,8char,1/16
	out	(USARTC),a
	ld	a,0b00110111		;RxEnable,TxEnable,RTS=0,DTR=0
	out	(USARTC),a
	ret
ppi_init:
	ld	a,0b10000011		;PPIA mode0,output PPIB mode0,input
	out	(PPICNT),a		;PPIC C7-C4 output,C3-C0 input
	ret	

8251の1byte入出力ルーチンを変更します。

getchar:
	in     	a,(USARTC)
        bit	1,a
        jr      z,getchar
        in      a,(USARTD)
	ret

putchar:push	af
putchar01:
	in      a,(USARTC)
        bit     0,a
        jr      z,putchar01
	pop	af
        out     (USARTD),a
	ret

これで変更が行えたので、romに焼いて起動してみました。

Monitor Z80+8251+8255 ver0.71  by Pinecone 2020/09/01
>?                                                                              
? Help                                                                          
d MemoryDump                                                                    
m MemoryChange                                                                  
l HexFileLoad                                                                   
j jump                                                                      |
i I/oRegister                                                             
c Call                                                                          
>m 8000 00 ff                                                             
>m 8000 FF 
>

以下ソースファイルを展開しました。

; Z80+82C51+8255 monitor  ver0.71 by Pinecone 2020/09/01
;
; Z80 cpu
; rom 0000h -- 7fffh
; ram 8000h -- ffffh
; External clock 4.9142MHz

; 8251 serial communication 
; extemal Clock 0.6144MHz (1/16=38400bps)
 

; assembler
;  program start 0000H
;  main          0100H
;
; assemblers  ASxxxx and ASlink V5.10
; file name Z80_8251_moni.asm
; $ asz80 -l -s -o Z80_8251_moni.asm
; $ aslink -i Z80_8251_moni
; windows10 rom-writer TL866-2 plus Z80_8251_moni.ihx
;

        .z80
 
        .area TEST(ABS)
;; 8251
USARTD	.equ	0x84	;USART DATA REG
USARTC	.equ	0x85	;USART CONTL REG

;;8255
PPIA 		.equ 	0x88		;PPI-A PORT DATA REG
PPIB		.equ	0x89		;PPI-B PORT DATA REG
PPIC		.equ	0x8a		;PPI-C PORT DATA REG
PPICNT		.equ	0x8b		;PPI  CONTL REG


        .org    0x0000
        jp      start
 
        .org    0x0100

start:                          ;cold start

        ld      sp,0x0000       ;stack pointer set
        call    usart_init      ;serial channel initialize
	call	ppi_init	;Parallel port  initialize
        ld      hl,msg_op       ;opening message display
        call    msgout
prompt: ld      a,">"           ;main  routine
        call    putchar         ;prompt display
        call    getchar
        call    putchar
        cp      "?"             ;help ?
        call    z,help
        cp      "d"             ;memory display?
        call    z,dump
        cp      "m"             ;memory rewrite ?
        call    z,memory
        cp      "l"             ;hex file load?
        call    z,loadhex       
        cp      "j"             ;address jump?
        call    z,jump
        cp	"i"		;i/o register rewite
        call	z,ioreg
        cp	"c"
        call	z,calling	;address call
        cp      0x0d
        jr	z,prompt
        cp 	0x00
        jr	z,prompt
        call	cr
        jr      prompt

help:   ld      hl,help_msg     ;help ?
        call    msgout
        ret
cr:
        ld	a,0x0d
        call	putchar
        ret

jump:                           ;address jump?
        ld      a," "
        call    putchar
        call    input_hl        ;dump address input
        cp      0x00
        jr      nz,crret
        ld      a," "
        call    putchar
        ld      a,"y"
        call    putchar
        ld      a,":"

        call    putchar
        call    getchar
        cp      "y"
        jr      nz,crret
        call    cr
        jp      (HL)       
crret:
        call    cr
        ret

calling:                         ;address call?
        ld      a," "
        call    putchar
        call    input_hl       	 ;call address input
        cp      0x00
        jr      nz,crret
        ld      a," "
        call    putchar
        ld      a,"y"
        call    putchar
        ld      a,":"
        call    putchar
        call    getchar
        cp      "y"
        jr      nz,crret
        call	cr
        ld	de,callret
        push	de
        jp	(HL)
callret:
        ret


loadhex:
        call    loadhexline     ;load 1line Hex file
        cp      0xff            ;hex file read err
        jr      z,loadhexerr
        cp      0x01            ;hex file end?
        jr      nz,loadhex
        ld      a,0x0d
        call    putchar
        ld      a,"O"
        call    putchar
        ld      a,"K"
        call    putchar
        ld      a,0x0d
        call    putchar
        ret

loadhexerr:
        ld      a,0x0d          ;hex file read skip
        call    putchar
        ld      a,"E"
        call    putchar
        ld      a,"R"
        call    putchar
        ld      a,"R"
        call    putchar
        ld      a,0x0d
        call    putchar
        ret
        
loadhexline:
        ld      a,0x0d
        call    putchar
        ld      d,0x00          ;checksum count clr
        call    getchar         ;record mark is ":"
        cp      ":"
        jr      nz,loadhexlineerr
        call    input_l         ;data size 1byte
        ld      b,l             ;checksum = checksum + data size
        ld      a,d
        add     b
        ld      d,a
        call    input_hl        ;offset address 2byte
        push    hl
        pop     ix              ;offset address HLreg >> IXreg
        ld      a,d             ;checksum = checksum + address Low      
        add     l               
        add     h               ;checksum = checksum + address Hi
        ld      d,a
        call    input_l         ;record type
        ld      a,l
        cp      0x00            ;data record
        jr      nz,checkrecord

        ;; *** data record job ****
data_hex:
        call    input_l         ;read hex 1byte in Lreg(hex)
        ld      (ix),l          ;offset address < hex data
        inc     ix              ;offset address +1
        ld      a,l
        add     d               ;cheksum Dreg = Dreg + Lreg
        ld      d,a
        djnz    data_hex        ;Breg(data size) == 0?
        call    input_l         ;chechsum OK?
        ld      a,d
        add     l
        cp      0x00
        jr      nz,loadhexlineerr
        call    getchar
        cp      0x0a            ;load 1line hex LF?
        jr      nz,loadhexlineerr
        ld      a,0x00
        ret

checkrecord:                    ;end record ?
        cp      0x01
        jr      nz,loadhexlineerr
        call    input_l
        ld      a,l
        cp      0xff
        jr      nz,loadhexlineerr
        ld      a,0x01
        ret

loadhexlineerr:
        ld      a,0xff          ;read record err (no support)
        ret     

dump:                           ;memory dump
        ld      a," "
        call    putchar
        call    input_hl        ;dump address input
        cp      0x00
        jr      z,dump1
        push    iy              ;memory dump address set
        pop     hl
dump1:
        call    dump_hl         ;memory dump
        push    hl              ;memory address IY set
        pop     iy
        ret

memory:                         ;memory change
        ld      a," "           ;space
        call    putchar         
        call    input_hl        ;change memory address 
        cp      0x00
        jr      z,memory1       ;no address hex code 
        ld      a,0x0d
        call    putchar
        ret
memory1:
        ld      a," "           ;current memory display
        call    putchar
        ld      a,(HL)
        call    hex_a_disp
        ld      a," "
        call    putchar
        push    hl
        call    input_l         ;new memory conntents input
        cp      0x00
        jr      z,memory2
        pop     hl
        xor	a
        ret
memory2:
        ld      c,l             ;memory contents update
        pop     hl
        ld      (hl),c
        ld      a,0x0d
        call    putchar
        ret

ioreg:                         ;ioreg change
        ld      a," "           ;space
        call    putchar
        call    input_l        ;change i/o register
        cp      0x00
        jr      z,ioreg1       ;no address hex code
        ld      a,0x0d
        call    putchar
        ret
ioreg1:
        ld      a," "           ;current i/o address display
        call    putchar
        ld	b,0x00
        ld	c,l
        in      a,(c)
        call    hex_a_disp
        ld      a," "
        call    putchar
        call    input_l         ;new i/o conntents address input
        cp      0x00
        jr      z,ioreg2
        xor	a
        ret
ioreg2:
        ld      a,l             ;new i/o address update
        out     (c),a
        ld      a,0x0d
        call    putchar
        ret


input_l:                        ;input Lreg hex (1byte)
        push    bc
        ld      b,0x02
        jr      input_loop

input_hl:                       ;input HLreg hex (2byte)
        push    bc
        ld      b,0x04
input_loop:
        ld      hl,0x0000       ;HL reg cler
        jr      input_hl2
shift_hl:
        add     hl,hl           ;HL reg shift left 4bit
        add     hl,hl
        add     hl,hl
        add     hl,hl
input_hl2:
        call    getchar         ;input ascii hex 1char
        call    putchar
        call    ascii_hex       ;ascii hex 1char >> Areg
        cp      0xff
        jr      z,input_hl_err
        and     0x0f            ;Areg low order 4bit >> Lreg
        or      l
        ld      l,a
        djnz    shift_hl
input_hl_end:
        pop     bc
        xor     a               ;OK >> Areg 0x00
        ret
input_hl_err:
        ld      a,0xff          ;NG >> Areg 0xff
        pop     bc
        ret

dump_hl:                        ;memory dump 1line(+0 -- +f)
        ld      a,0x0d
        call    putchar
        push    hl
        ld      hl,dump_msg     ;dump address msg output
        call    msgout
        pop     hl

        ld      a,h             ;dump address HLreg
        call    hex_a_disp      ;dump address output
        ld      a,l
        call    hex_a_disp
        ld      a," "
        call    putchar
        call    putchar
        ld      b,0x10          ;address --> address +0f
hl_disp:
        ld      a,(HL)          ;dump addres data (HL)
        inc     HL
        call    hex_a_disp
        ld      a," "
        call    putchar
        djnz    hl_disp

        ld      a,0x0d
        call    putchar
        ret

hex_a_disp:                     ;Areg(HEX) >> putchar(areg)
        push    af
        rrca                    ;7-4bit Right shift
        rrca
        rrca
        rrca
        call    hex_ascii       ;3-0bit Hex >> Hex ascii(0-F)
        call    putchar         ;7-4bit putchar
        pop     af
        call    hex_ascii       ;3-0bit Hex >> Hex ascii(0-F)
        call    putchar         ;3-0bit putchar
        ret


ascii_hex:
        sub     0x30
        jr      c,err_hex
        cp      0x0A            ;0-9
        jr      c,hex_1_9
        sub     0x11
        cp      0x06            ;A-F
        jr      c,hex_A_F
        sub     0x20
        cp      0x06            ;a-f
        jr      nc,err_hex
hex_A_F:
        add     0x0a
hex_1_9:
        ret
err_hex:ld      a,0xff
        ret

hex_ascii:                      ;Areg(HEX) >> Areg(ascii code)  
        and     a,0x0f
        cp      0x0a
        jr      c,ascii0_9
        add     0x37
        ret
ascii0_9:
        add     0x30
        ret

                        
        
msgout:
        ld      a,(hl)          ;(HL)reg is output disp at 0x00
        cp      0x00
        ret     z
        call    putchar
        inc     hl
        jr      msgout


getchar:
	in     	a,(USARTC)
        bit	1,a
        jr      z,getchar
        in      a,(USARTD)
	ret

putchar:push	af
putchar01:
	in      a,(USARTC)
        bit     0,a
        jr      z,putchar01
	pop	af
        out     (USARTD),a
	ret

;

usart_init:
	xor	a
	ld	b,3
usartinit01:
	out	(USARTC),a		;dummy command
	djnz	usartinit01
	ld	a,0b01000000		;reset commmand 
	out	(USARTC),a
	ld	a,0b01001110		;1 stop bit,Parity disble,8char,1/16
	out	(USARTC),a
	ld	a,0b00110111		;RxEnable,TxEnable,RTS=0,DTR=0
	out	(USARTC),a
	ret
ppi_init:
	ld	a,0b10000011		;PPIA mode0,output PPIB mode0,input
	out	(PPICNT),a		;PPIC C7-C4 output,C3-C0 input
	ret	
;

msg_op: .str    "Monitor Z80+8251+8255 ver0.71  by Pinecone 2020/09/01"
        .db     0x0d
        .db     0x00
help_msg:
        .db     0x0d    
        .str    "? Help"
        .db     0x0d
        .str    "d MemoryDump"
        .db     0x0d
        .str    "m MemoryChange"
        .db     0x0d
        .str    "l HexFileLoad"
        .db     0x0d
        .str    "j jump"
        .db     0x0d
        .str	"i I/oRegister"
        .db	0x0d
        .str	"c Call"
        .db	0x0d	
        .db     0x00
dump_msg:
        .str    "addr  +0 +1 +2 +3 +4 +5 +6 +7 +8 +9 +A +B +C +D +E +F"
        .db     0x0d
        .db     0x00

	.end

アセンブルしたHEXファイルは下記の通りです。

:03000000C3000139
:20010000310000CD7203CD8603218B03CD54033E3ECD6703CD5E03CD6703FE3FCC4A01FED9
:2001200064CC3F02FE6DCC5502FE6CCCAC01FE6ACC5701FE69CC8902FE63CC8101FE0D28B1
:20014000CEFE0028CACD510118C521C203CD5403C93E0DCD6703C93E20CD6703CDC402FEA1
:2001600000201A3E20CD67033E79CD67033E3ACD6703CD5E03FE792004CD5101E9CD510123
:20018000C93E20CD6703CDC402FE0020F03E20CD67033E79CD67033E3ACD6703CD5E03FE02
:2001A0007920DACD510111AB01D5E9C9CDE601FEFF2819FE0120F53E0DCD67033E4FCD6720
:2001C000033E4BCD67033E0DCD6703C93E0DCD67033E45CD67033E52CD67033E52CD670347
:2001E0003E0DCD6703C93E0DCD67031600CD5E03FE3A2048CDBF02457A8057CDC402E5DDD5
:20020000E17A858457CDBF027DFE002020CDBF02DD7500DD237D825710F3CDBF027A85FE16
:20022000002019CD5E03FE0A20123E00C9FE01200BCDBF027DFEFF20033E01C93EFFC93E75
:2002400020CD6703CDC402FE002803FDE5E1CDEA02E5FDE1C93E20CD6703CDC402FE002835
:20026000063E0DCD6703C93E20CD67037ECD1B033E20CD6703E5CDBF02FE002803E1AFC9A5
:200280004DE1713E0DCD6703C93E20CD6703CDBF02FE0028063E0DCD6703C93E20CD670345
:2002A00006004DED78CD1B033E20CD6703CDBF02FE002802AFC97DED793E0DCD6703C9C5E5
:2002C00006021803C50604210000180429292929CD5E03CD6703CD2E03FEFF2809E60FB510
:2002E0006F10E9C1AFC93EFFC1C93E0DCD6703E5211104CD5403E17CCD1B037DCD1B033EE7
:2003000020CD6703CD670306107E23CD1B033E20CD670310F43E0DCD6703C9F50F0F0F0F98
:20032000CD4803CD6703F1CD4803CD6703C9D6303813FE0A380ED611FE063806D620FE06A3
:200340003003C60AC93EFFC9E60FFE0A3803C637C9C630C97EFE00C8CD67032318F6DB8502
:20036000CB4F28FADB84C9F5DB85CB4728FAF1D384C9AF0603D38510FC3E40D3853E4ED32E
:20038000853E37D385C93E83D38BC94D6F6E69746F72205A38302B383235312B3832353596
:2003A00020766572302E3731202062792050696E65636F6E6520323032302F30392F303192
:2003C0000D000D3F2048656C700D64204D656D6F727944756D700D6D204D656D6F72794325
:2003E00068616E67650D6C2048657846696C654C6F61640D6A206A756D700D6920492F6F6C
:2004000052656769737465720D632043616C6C0D006164647220202B30202B31202B32202F
:200420002B33202B34202B35202B36202B37202B38202B39202B41202B42202B43202B441F
:08044000202B45202B460D0086
:00000001FF

最初のモニタが起動できたので、次回はROMからRAMに切り替え64KフルRAMになるか確認したいと思います。

おすすめの記事